Как создать общую библиотеку с cmake?

Я написал библиотеку, которую я использовал для компиляции с использованием самописного Makefile, но теперь я хочу переключиться на cmake. Дерево выглядит так (я удалил все ненужные файлы):

.
├── include
│   ├── animation.h
│   ├── buffers.h
│   ├── ...
│   ├── vertex.h
│   └── world.h
└── src
    ├── animation.cpp
    ├── buffers.cpp
    ├── ...
    ├── vertex.cpp
    └── world.cpp

Так что я пытаюсь сделать, это просто скомпилировать исходный код в общую библиотеку, а затем установить его с помощью файлов заголовков.

Большинство примеров, которые я нашел, компилируют исполняемые файлы с некоторыми разделяемыми библиотеками, но не просто обычную общую библиотеку. Было бы также полезно, если бы кто-то мог просто сказать мне очень простую библиотеку, которая использует cmake, поэтому я могу использовать это в качестве примера.

Ответ 1

Всегда указывайте минимально необходимую версию cmake

cmake_minimum_required(VERSION 3.9)

Вы должны объявить проект. cmake говорит, что это обязательно, и он будет определять удобные переменные PROJECT_NAME, PROJECT_VERSION и PROJECT_DESCRIPTION (эта последняя переменная требует cmake 3.9):

project(mylib VERSION 1.0.1 DESCRIPTION "mylib description")

Объявите новую библиотечную цель. Пожалуйста, избегайте использования file(GLOB ...). Эта функция не обеспечивает мастерства в процессе компиляции. Если вы ленивый, скопируйте и вставьте вывод ls -1 sources/*.cpp:

add_library(mylib SHARED
    sources/animation.cpp
    sources/buffers.cpp
    [...]
)

Установите свойство VERSION (необязательно, но это хорошая практика):

set_target_properties(mylib PROPERTIES VERSION ${PROJECT_VERSION})

Вы также можете установить SOVERSION на основной номер VERSION. Так что libmylib.so.1 будет символической ссылкой на libmylib.so.1.0.0.

set_target_properties(mylib PROPERTIES SOVERSION 1)

Объявите публичный API вашей библиотеки. Этот API будет установлен для стороннего приложения. Рекомендуется изолировать его в дереве проекта (например, поместить его в каталог include/). Обратите внимание, что частные заголовки не следует устанавливать, и я настоятельно рекомендую размещать их вместе с исходными файлами.

set_target_properties(mylib PROPERTIES PUBLIC_HEADER include/mylib.h)

Если вы работаете с подкаталогами, не очень удобно включать относительный путь, например "../include/mylib.h". Итак, передайте верхний каталог во включенные каталоги:

target_include_directories(mylib PRIVATE .)

или

target_include_directories(mylib PRIVATE include)
target_include_directories(mylib PRIVATE src)

Создайте правило установки для своей библиотеки. Я предлагаю использовать переменные CMAKE_INSTALL_*DIR, определенные в GNUInstallDirs:

include(GNUInstallDirs)

И объявить файлы для установки:

install(TARGETS mylib
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

Вы также можете экспортировать файл pkg-config. Эти файлы позволяют стороннему приложению легко импортировать вашу библиотеку:

с Makefile, см. pkg-config
с помощью Autotools см. PKG_CHECK_MODULES
с помощью cmake, см. pkg_check_modules

Создайте файл шаблона с именем mylib.pc.in (см. справочную страницу pc (5) для получения дополнительной информации):

[email protected][email protected]
[email protected][email protected]
libdir=${exec_prefix}/@[email protected]
includedir=${prefix}/@[email protected]

Name: @[email protected]
Description: @[email protected]
Version: @[email protected]

Requires:
Libs: -L${libdir} -lmylib
Cflags: -I${includedir}

В свой CMakeLists.txt добавьте правило для расширения макроса @ (@ONLY просит cmake не расширять переменные вида ${VAR}):

configure_file(mylib.pc.in mylib.pc @ONLY)

И, наконец, установите сгенерированный файл:

install(FILES ${CMAKE_BINARY_DIR}/mylib.pc DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/pkgconfig)

Вы также можете использовать функцию cmake EXPORT. Однако эта функция совместима только с cmake, и мне трудно ее использовать.

Наконец, весь CMakeLists.txt должен выглядеть следующим образом:

cmake_minimum_required(VERSION 3.9)
project(mylib VERSION 1.0.1 DESCRIPTION "mylib description")
include(GNUInstallDirs)
add_library(mylib SHARED src/mylib.c)
set_target_properties(mylib PROPERTIES
    VERSION ${PROJECT_VERSION}
    SOVERSION 1
    PUBLIC_HEADER api/mylib.h)
configure_file(mylib.pc.in mylib.pc @ONLY)
target_include_directories(mylib PRIVATE .)
install(TARGETS mylib
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
install(FILES ${CMAKE_BINARY_DIR}/mylib.pc
    DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/pkgconfig)

Ответ 2

Этот минимальный файл CMakeLists.txt компилирует простую общую библиотеку:

cmake_minimum_required(VERSION 2.8)

project (test)
set(CMAKE_BUILD_TYPE Release)

include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)
add_library(test SHARED src/test.cpp)

Однако у меня нет опыта копирования файлов в другое место назначения с помощью CMake. Команда file с подписью COPY/INSTALL выглядит так, как будто она может быть полезна.

Ответ 3

Я пытаюсь понять, как это сделать сам, и, похоже, вы можете установить библиотеку следующим образом:

cmake_minimum_required(VERSION 2.4.0)

project(mycustomlib)

# Find source files
file(GLOB SOURCES src/*.cpp)

# Include header files
include_directories(include)

# Create shared library
add_library(${PROJECT_NAME} SHARED ${SOURCES})

# Install library
install(TARGETS ${PROJECT_NAME} DESTINATION lib/${PROJECT_NAME})

# Install library headers
file(GLOB HEADERS include/*.h)
install(FILES ${HEADERS} DESTINATION include/${PROJECT_NAME})

Ответ 4

Во-первых, это макет каталога, который я использую:

.
├── include
│   ├── class1.hpp
│   ├── ...
│   └── class2.hpp
└── src
    ├── class1.cpp
    ├── ...
    └── class2.cpp

После нескольких дней изучения этого, это мой любимый способ сделать это благодаря современному CMake:

cmake_minimum_required(VERSION 3.5)
project(mylib VERSION 1.0.0 LANGUAGES CXX)

set(DEFAULT_BUILD_TYPE "Release")

if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  message(STATUS "Setting build type to '${DEFAULT_BUILD_TYPE}' as none was specified.")
  set(CMAKE_BUILD_TYPE "${DEFAULT_BUILD_TYPE}" CACHE STRING "Choose the type of build." FORCE)
  # Set the possible values of build type for cmake-gui
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
endif()

include(GNUInstallDirs)

set(SOURCE_FILES src/class1.cpp src/class2.cpp)

add_library(${PROJECT_NAME} ...)

target_include_directories(${PROJECT_NAME} PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:include>
    PRIVATE src)

set_target_properties(${PROJECT_NAME} PROPERTIES
    VERSION ${PROJECT_VERSION}
    SOVERSION 1)

install(TARGETS ${PROJECT_NAME} EXPORT MyLibConfig
    ARCHIVE  DESTINATION ${CMAKE_INSTALL_LIBDIR}
    LIBRARY  DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME  DESTINATION ${CMAKE_INSTALL_BINDIR})
install(DIRECTORY include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME})

install(EXPORT MyLibConfig DESTINATION share/MyLib/cmake)

export(TARGETS ${PROJECT_NAME} FILE MyLibConfig.cmake)

После запуска CMake и установки библиотеки нет необходимости использовать Find ***. Cmake files, ее можно использовать так:

find_package(MyLib REQUIRED)

#No need to perform include_directories(...)
target_link_libraries(${TARGET} mylib)

Что если он установлен в стандартном каталоге, он будет найден, и больше ничего не нужно будет делать. Если он был установлен по нестандартному пути, это также легко, просто сообщите CMake, где найти MyLibConfig.cmake, используя:

cmake -DMyLib_DIR=/non/standard/install/path ..

Надеюсь, это поможет всем так же, как и мне. Старые способы сделать это были довольно громоздкими.