Как я могу передать аргументы в командный файл?

Мне нужно передать идентификатор и пароль в пакетный файл во время выполнения, а не жестко запрограммировать их в файл.

Вот как выглядит командная строка:

test.cmd admin [email protected] > test-log.txt

Ответ 1

Вот как я это сделал:

@fake-command /u %1 /p %2

Вот как выглядит команда:

test.cmd admin [email protected] > test-log.txt

%1 применяется к первому параметру, %2 (и здесь сложная часть) применяется ко второму. Таким способом можно передать до 9 параметров.

Ответ 2

Еще один полезный совет - использовать %* для обозначения "все". Например:

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

Когда вы бежите:

test-command admin password foo bar

вышеуказанный командный файл будет работать:

fake-command /u admin /p password admin password foo bar

У меня может быть немного неправильный синтаксис, но это общая идея.

Ответ 3

Если вы хотите разумно обрабатывать отсутствующие параметры, вы можете сделать что-то вроде:

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

Ответ 4

Доступ к пакетным параметрам может быть простым с% 1,% 2,...% 9 или также% *,
но только если содержание простое.

Для сложного содержимого, такого как "&"^&, простого способа не существует, так как невозможно получить доступ к% 1 без возникновения ошибки.

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

Линии расширяются до

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

И каждая строка терпит неудачу, так как одна из & находится вне кавычек.

Это можно решить с помощью чтения из временного файла отмеченной версии параметра.

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

Хитрость заключается в том, чтобы включить echo on и развернуть% 1 после оператора rem (работает также с %2.. %*).
Таким образом, даже "&"& может отображаться без ошибки, как отмечается.

Но чтобы иметь возможность перенаправить вывод echo on, вам нужны два цикла for.

Дополнительные символы * # используются для защиты содержимого вроде /? (показал бы помощь для REM).
Или символ ^ в конце строки может работать как многострочный символ, даже после rem.

Затем читаем параметр rem из файла, но внимательно.
FOR/F должен работать с отложенным расширением, иначе содержимое с "!" будет уничтожен.
После удаления лишних символов в param1 вы его получили.

И для безопасного использования param1 включите отложенное расширение.

Ответ 5

Да, и просто не забудьте использовать переменные типа %%1 при использовании if и for и банды.

Если вы забудете double %, вы замените (возможно, нулевым) аргументы командной строки и получите некоторые довольно запутанные сообщения об ошибках.

Ответ 6

Нет необходимости усложнять его. Это просто команда% 1% 2 параметров, например,

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

В "паузе" отображается то, что сделал командный файл, и ждет, пока вы нажмете клавишу ANY. Сохраните это как xx.bat в папке Windows.

Чтобы использовать его, введите, например:

xx c:\f\30\*.* f:\sites\30

Этот командный файл выполняет все необходимые параметры, такие как копирование только новых файлов и т.д. Я использовал его до Windows. Если вам нравится видеть имена файлов, поскольку они копируются, оставьте параметр Q.

Ответ 7

В последнее время друг спрашивал меня об этой теме, поэтому я решил опубликовать, как обрабатывать аргументы командной строки в пакетных файлах.

Этот метод имеет немного накладных расходов, как вы увидите, но это делает мои командные файлы очень легкими для понимания и быстрого внедрения. Помимо поддержки следующих структур:

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

Суть его имеет функции :init, :parse и :main.

Пример использования

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof

Ответ 8

@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue

Примечание: IF "%1"=="" вызовет проблемы, если %1 заключен в кавычки.

В этом случае используйте IF [%1]==[] или, только в NT 4 (SP6) и позже, IF "%~1"=="".

Ответ 9

Пусть это просто.

Вот файл .cmd.

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

Вот 3 вызова из командной строки.

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>

Ответ 10

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

Это указывает на параметры партии (% *), либо они цитируются, либо нет, а затем эхо каждого параметра.

Ответ 11

Я написал простой read_params script, который может быть вызван как функция (или внешний .bat) и поместит все переменные в текущую среду. Он не будет изменять исходные параметры, потому что функция call ed с копией исходных параметров.

Например, с учетом следующей команды:

myscript.bat some -random=43 extra -greeting="hello world" fluff

myscript.bat сможет использовать переменные после вызова функции:

call :read_params %*

echo %random%
echo %greeting%

Здесь функция:

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

Ограничения

Невозможно загрузить аргументы без значения, например -force. Вы можете использовать -force=true, но я не могу придумать способ разрешить пустые значения, не зная список параметров загодя, которые не будут иметь значения.

Changelog

2/18/2016
- Больше не требуется отсроченное расширение
- Теперь работает с другими аргументами командной строки, ища - перед параметрами.

Ответ 12

Чтобы сослаться на переменную set в командной строке, вам нужно использовать %a% например:

set a=100 
echo %a%  
rem output = 100

Примечание: это работает для Windows 7 Pro.

Ответ 13

Вдохновленный ответом в другом месте @Jon, я разработал более общий алгоритм для извлечения именованных параметров, необязательных значений и переключателей.

Допустим, мы хотим реализовать утилиту foobar. Требуется начальная команда. Он имеет необязательный параметр --foo который принимает необязательное значение (которое, конечно, не может быть другим параметром); если значение отсутствует, по default по default. Он также имеет необязательный параметр --bar который принимает требуемое значение. Наконец, он может принимать флаг --baz без допустимого значения. Ох, и эти параметры могут прийти в любом порядке.

Другими словами, это выглядит так:

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

Вот решение:

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

Используйте SETLOCAL чтобы переменные не SETLOCAL в вызывающую среду.
Не забудьте инициализировать переменные SET FOO= и т.д., Если кто-то определил их в вызывающей среде.
Используйте %~1 чтобы удалить кавычки.
Используйте IF "%ARG%" == "" а не IF [%ARG%] == [] потому что [ и ] не играют вообще, значения заканчиваются пробелом.
Даже если вы SHIFT внутри блока IF, текущие аргументы, такие как %~1, не обновляются, потому что они определяются при анализе IF. Вы можете использовать %~1 и %~2 внутри блока IF, но это может сбить с толку, потому что у вас есть SHIFT. Вы можете поместить SHIFT в конец блока для ясности, но это может потеряться и/или сбить людей с толку. Так что "захват" %~1 и %~1 вне блока кажется лучшим.
Вы не хотите использовать параметр вместо необязательного значения другого параметра, поэтому вам нужно проверить, IF NOT "%ARG:~0,2%" == "--".
Будьте внимательны только к SHIFT когда используете один из параметров.
Дублированный код SET FOO=%DEFAULT_FOO% вызывает сожаление, но альтернативой может быть добавление IF "%FOO%" == "" SET FOO=%DEFAULT_FOO% вне блока IF NOT "%ARG%" == "", Однако, поскольку он все еще находится внутри блока IF "%PARAM%" == "--foo", значение %FOO% было бы оценено и установлено до того, как вы в него --foo, поэтому вы никогда не обнаружите, что оба --foo присутствовал параметр, а также отсутствовало значение %FOO%.
Обратите внимание, что ECHO Missing bar value. 1>&2 ECHO Missing bar value. 1>&2 отправляет сообщение об ошибке в stderr.
Хотите пустую строку в командном файле Windows? Вы должны использовать ECHO: или один из вариантов.

Ответ 14

Создайте новый командный файл (пример: openclass.bat) и напишите эту строку в файле:

java %~n1

Затем поместите пакетный файл, скажем, в папку system32, перейдите в свой файл класса Java, щелкните правой кнопкой мыши, "Свойства", "Открыть с...", затем найдите пакетный файл, выберите его и... /p >

Это работает для меня.

PS: Я не могу найти способ закрыть окно cmd, когда я закрываю Java-класс. На данный момент...

Ответ 15

Простое решение (хотя вопрос старый)

Test1.bat

echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause

CallTest1.bat

call "C:\Temp\Test1.bat" pass123

выход

YourLocalPath>call "C:\Temp\test.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .

Где YourLocalPath - это текущий путь к каталогу.

Для простоты сохраните команду param в переменной и используйте переменную для сравнения.

Его не просто написать, но и просто поддерживать, поэтому, если позже какой-то другой человек или вы прочтете свой сценарий через длительный период времени, его будет легко понять и поддерживать.

Чтобы написать код в строке: см. Другие ответы.

Ответ 16

Для использования циклов получить все аргументы и в чистом пакетном режиме:

@echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift && for /l %%l in (!_cnt! 1 !_cnt!) do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof

Ваш код готов сделать что-то с номером аргумента там, где это нужно, например...

 @echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift 

 )

 fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt

Ответ 17

Что если я хочу передать более 9 параметров? Я использую 10 параметров в одном скрипте, но параметр номер 10 отображается как "10"

set var=%10

echo %var%

РЕЗУЛЬТАТ

Ожидаемый результат и id, как обернуть% {10}

Ответ 18

В пакетном файле

set argument1=%1
set argument2=%2
echo %argument1%
echo %argument2%

% 1 и% 2 возвращают первое и второе значения аргумента соответственно.

И в командной строке передайте аргумент

Directory> batchFileName admin [email protected]

Вывод будет

admin
[email protected]