Самый простой способ поменять местами две строки в Vim?

Каков самый простой способ заменить все вхождения string_a на string_b, в то же время изменив все, что уже было string_b на string_a? Мой текущий метод выглядит следующим образом:

:s/string_a/string_c/g  
:s/string_b/string_a/g  
:s/string_c/string_b/g

Несмотря на то, что это работает, для этого требуется дополнительная набраковка и кажется неэффективной. Кто-нибудь знает лучший способ сделать это?

Ответ 1

Я бы сделал это вот так:

:%s/\v(foo|bar)/\={'foo':'bar','bar':'foo'}[submatch(0)]/g

Но это слишком много печатает, поэтому я бы сделал это:

function! Mirror(dict)
    for [key, value] in items(a:dict)
        let a:dict[value] = key
    endfor
    return a:dict
endfunction

function! S(number)
    return submatch(a:number)
endfunction

:%s/\v(foo|bar)/\=Mirror({'foo':'bar'})[S(0)]/g

Но это все еще требует дважды набирать foo и bar, поэтому я бы сделал что-то вроде этого:

function! SwapWords(dict, ...)
    let words = keys(a:dict) + values(a:dict)
    let words = map(words, 'escape(v:val, "|")')
    if(a:0 == 1)
        let delimiter = a:1
    else
        let delimiter = '/'
    endif
    let pattern = '\v(' . join(words, '|') . ')'
    exe '%s' . delimiter . pattern . delimiter
        \ . '\=' . string(Mirror(a:dict)) . '[S(0)]'
        \ . delimiter . 'g'
endfunction

:call SwapWords({'foo':'bar'})

Если одно из ваших слов содержит /, вы должны передать разделитель, который, как вы знаете, не содержит ни одного из ваших слов,.e.g

:call SwapWords({'foo/bar':'foo/baz'}, '@')

Это также имеет преимущество в том, что вы можете менять сразу несколько пар слов.

:call SwapWords({'foo':'bar', 'baz':'quux'})

Ответ 2

Вы можете сделать это легко с помощью Тима Папа Abolish плагин

:%S/{transmit,receive}/{receive,transmit}

Ответ 3

swapstrings plugin предоставляет удобную команду для этого:

:SwapStrings string_a string_b

Ответ 4

Вот как я поменяю два слова skip и limit.

%s/skip/xxxxx/g|%s/limit/skip/g|%s/xxxxx/limit/g

Довольно уверен, что кто-то может превратить его в более короткую команду, которая принимает два аргумента.

Ответ 5

Вы можете сделать это с помощью одной команды, как показано в моем коде ниже:

:%s/\<\(string_a\|string_b\)\>/\=strpart("string_bstring_a", 8 * ("string_b" == submatch(0)), 8)/g

Обновление: редактор здесь, в stackoverflow, сводит меня с ума, потому что он держит удаление backslahes...