Могу ли я использовать регулярные выражения Perl для соответствия сбалансированному тексту?

Ответ 1

Это официальный ответ за минусом любых последующих изменений.

Первой попыткой, вероятно, должен быть модуль Text::Balanced, который находится в стандартной библиотеке Perl с Perl 5.8. Он имеет множество функций для обработки сложного текста. Модуль Regexp::Common также может помочь, предоставляя консервированные шаблоны, которые вы можете использовать.

Начиная с Perl 5.10, вы можете сопоставлять сбалансированный текст с регулярными выражениями с использованием рекурсивных шаблонов. До Perl 5.10 вам приходилось прибегать к различным трюкам, таким как использование Perl-кода в последовательности (??{}).

Здесь приведен пример использования рекурсивного регулярного выражения. Цель состоит в том, чтобы зафиксировать весь текст в угловых скобках, включая текст во вложенных угловых скобках. В этом примере текста есть две "основные" группы: группа с одним уровнем вложенности и группа с двумя уровнями вложенности. В угловых скобках имеется пять групп:

I have some <brackets in <nested brackets> > and
<another group <nested once <nested twice> > >
and that it.

Регулярное выражение для соответствия сбалансированному тексту использует две новые функции регулярного выражения (для Perl 5.10). Они описаны в perlre, и этот пример является модифицированной версией той, что содержится в этой документации.

Во-первых, добавление нового притяжательного + к любому квантификатору находит самое длинное совпадение и не отступает. Это важно, так как вы хотите обрабатывать любые угловые скобки через рекурсию, а не назад. Группа [^<>]++ находит один или несколько неугольных скобок без обратного слежения.

Во-вторых, новый (?PARNO) относится к подматрице в конкретной группе захвата, заданной PARNO. В следующем регулярном выражении первая группа захвата находит (и запоминает) сбалансированный текст, и вам нужен тот же шаблон в первом буфере, чтобы пройти через вложенный текст. Это рекурсивная часть. (?1) использует шаблон во внешней группе захвата как независимую часть регулярного выражения.

Объединяя все вместе, у вас есть:

#!/usr/local/bin/perl5.10.0

my $string =<<"HERE";
I have some <brackets in <nested brackets> > and
<another group <nested once <nested twice> > >
and that it.
HERE

my @groups = $string =~ m/
        (                   # start of capture group 1
        <                   # match an opening angle bracket
            (?:
                [^<>]++     # one or more non angle brackets, non backtracking
                  |
                (?1)        # found < or >, so recurse to capture group 1
            )*
        >                   # match a closing angle bracket
        )                   # end of capture group 1
        /xg;

$" = "\n\t";
print "Found:\n\[email protected]\n";

Результат показывает, что Perl обнаружил две основные группы:

Found:
    <brackets in <nested brackets> >
    <another group <nested once <nested twice> > >

С небольшой дополнительной работой вы можете получить все группы в угловых скобках, даже если они находятся в других угловых скобках. Каждый раз, когда вы получаете сбалансированное совпадение, удаляйте его внешний разделитель (тот, который вы только что сопоставили, не повторяете его снова) и добавляете его в очередь строк для обработки. Продолжайте делать это, пока не получите совпадений:

#!/usr/local/bin/perl5.10.0

my @queue =<<"HERE";
I have some <brackets in <nested brackets> > and
<another group <nested once <nested twice> > >
and that it.
HERE

my $regex = qr/
        (                   # start of bracket 1
        <                   # match an opening angle bracket
            (?:
                [^<>]++     # one or more non angle brackets, non backtracking
                  |
                (?1)        # recurse to bracket 1
            )*
        >                   # match a closing angle bracket
        )                   # end of bracket 1
        /x;

$" = "\n\t";

while( @queue )
    {
    my $string = shift @queue;

    my @groups = $string =~ m/$regex/g;
    print "Found:\n\[email protected]\n\n" if @groups;

    unshift @queue, map { s/^<//; s/>$//; $_ } @groups;
    }

Вывод показывает все группы. Самые удаленные совпадения отображаются вверху и вложенные совпадения так далее:

Found:
    <brackets in <nested brackets> >
    <another group <nested once <nested twice> > >

Found:
    <nested brackets>

Found:
    <nested once <nested twice> >

Found:
    <nested twice>