Как написать пакетный файл с указанием пути к исполняемому файлу и версии Python для обработки сценариев Python в Windows?

Ответ 1

Здесь мое первое решение:

РЕШЕНИЕ 1

@echo off
set test_script=.pyexe.py
rem Let create temporary Python script which prints info we need
echo from __future__ import print_function; import sys; print(sys.executable); print(sys.version) > %test_script%
echo Python accessible through system PATH:
python %test_script%
echo ---
echo Python set as handler for Python files:
%test_script%
del %test_script%
set test_script=

Я столкнулся с проблемой с этим. Когда нет действительного интерпретатора Python, связанного с файлами Python, пытаясь открыть файл Python с помощью some_script.py, всплывает диалоговое окно "Открыть с системой". Для решения этой проблемы требуется очень хорошее знание пакетных файлов. Поэтому, пытаясь придумать решение, я задал следующие вопросы:

• Как предотвратить диалоговое окно "Открыть с" при открытии файла из окна команд?
• Как избежать переменных с круглыми скобками внутри if-предложения в пакетном файле?
• Почему отложенное расширение в пакетном файле не работает в этом случае?
• Как разделить строки с двойными кавычками со встроенными пространствами, разграниченными пробелами в пакетном файле?

Улучшенная версия исходного пакетного файла выглядит следующим образом:

РЕШЕНИЕ 1b

@echo off
setlocal
set test_script=.pyexe.py
rem Let create temporary Python script which prints info we need
echo from __future__ import print_function; import sys; print(sys.executable); print(sys.version) > %test_script%
echo Python accessible through the system PATH:
python %test_script%
echo ---
echo Python set as a handler for Python files:
rem We need to check if a handler set in the registry exists to prevent "Open With"
rem dialog box in case it doesn't exist
rem ftype Python.File hypothetical return value:
rem Python.File="%PYTHON_HOME%\python.exe" "%1" %*
for /f "tokens=2 delims==" %%i in ('ftype Python.File') do set reg_entry=%%i
rem ...now in 'reg_entry' variable we have everything after equal sign:
rem "%PYTHON_HOME%\python.exe" "%1" %*
set "handler="
setlocal enableDelayedExpansion
for %%A in (!reg_entry!) do if not defined handler endlocal & set handler=%%A
rem ...now in 'handler' variable we have the first token:
rem "%PYTHON_HOME%\python.exe"
rem Now we expand any environment variables that might be present
rem in the handler path
for /f "delims=" %%i in ('echo %handler%') do set expanded_handler=%%i
if exist "!expanded_handler!" (
    "%test_script%"
) else (
  if not "!handler!" == "!expanded_handler!" (
    set "handler=!expanded_handler! ^(!handler!^)"
  )
  echo Handler is set to !handler! which does not exist
)
del %test_script%

Это еще одно решение, позволяющее избежать проблем двух вышеперечисленных:

РЕШЕНИЕ 2

@echo off
setlocal
echo Python accessible through the system PATH:
where python
echo ---
echo Python set as a handler for Python source files (.py):
for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\.py /ve') do set "file_type=%%k"
for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\%file_type%\shell\open\command /ve') do echo %%k

... и улучшенная версия:

РЕШЕНИЕ 2b

@echo off
setlocal EnableDelayedExpansion
echo Python interpreter accessible through the system PATH:
where python
if not errorlevel 1 (
    python -c "from __future__ import print_function; import sys; print(sys.version)"
)
echo ---
echo Python interpreter registered as a handler for Python source files (.py):
reg query HKCR\.py /ve >nul 2>&1
if errorlevel 1 (
    echo No "HKEY_CLASSES_ROOT\.py" registry key found
) else (
    for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\.py /ve 2^>nul') do set "file_type=%%k"
    if "!file_type!"=="(value not set)" (
        echo "No file type set for .py extension"
    ) else (
        reg query HKCR\!file_type!\shell\open\command /ve >nul 2>&1
        if errorlevel 1 (
            echo No "HKEY_CLASSES_ROOT\!file_type!\shell\open\command" registry key found
        ) else (
            for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\!file_type!\shell\open\command /ve 2^>nul') do set "handler=%%k"
            if "!handler!"=="(value not set)" (
                echo No command set for !file_type!
            ) else (
                echo !handler!
            )
        )
    )
)

Ответ 2

Это может быть то, что вы ищете:

python -c "import sys; print sys.executable"