Как определить поддержку С++ 11 компилятора с CMake

Ответ 1

Если у вас есть версия CMake версии 3.1.0 или новее, вы можете определить, какие функции С++ ваш компилятор С++ поддерживает

cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
project(foobar CXX)
message("Your C++ compiler supports these C++ features:")
foreach(i ${CMAKE_CXX_COMPILE_FEATURES})
  message("${i}")
endforeach()

Но обычно вам не нужно использовать переменную CMake CMAKE_CXX_COMPILE_FEATURES в сценариях CMake. Вместо этого есть два способа сказать CMake, в соответствии с которыми С++ должен быть скомпилирован ваш файл на С++, либо явно указав стандарт С++ или указав требуемые функции С++ и дайте CMake индуцировать стандарт С++. CMake убедится, что компилятор С++ вызывается с правильными флагами командной строки (например, -std = С++ 11).

1. Явное указание стандарта С++

Вы можете явно указать стандарт С++, установив свойства CMake CXX_STANDARD  а также CXX_STANDARD_REQUIRED для вашей цели CMake.

$ cat /tmp/src/CMakeLists.txt
project(foobar CXX)
cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
add_executable(prog main.cc)
set_property(TARGET prog PROPERTY CXX_STANDARD 11)
set_property(TARGET prog PROPERTY CXX_STANDARD_REQUIRED ON)
$ cat /tmp/src/main.cc
int main() {
  return 0;
}
$ mkdir /tmp/build
$ cd /tmp/build
$ cmake /tmp/src
-- The CXX compiler identification is GNU 4.8.2
-- Check for working CXX compiler: /usr/bin/c++
-- Check for working CXX compiler: /usr/bin/c++ -- works
-- Detecting CXX compiler ABI info
-- Detecting CXX compiler ABI info - done
-- Detecting CXX compile features
-- Detecting CXX compile features - done
-- Configuring done
-- Generating done
-- Build files have been written to: /tmp/build
$ make VERBOSE=1 | grep main.cc | grep -- "-c"
/usr/bin/c++    -std=gnu++11 -o CMakeFiles/prog.dir/main.cc.o -c /tmp/src/main.cc
$

2. Указание необходимых функций С++ и CMake вызывать стандарт С++

Вы можете использовать команду CMake target_compile_features, чтобы указать функции С++, которые используются в вашей цели CMake. Из этого списка CMake будет вызывать стандарт С++, который будет использоваться. В глобальном свойстве CMake CMAKE_CXX_KNOWN_FEATURES перечислены возможности С++, которые вы можете выбрать.

cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
message("Your CMake version supports these C++ features:")
get_property(known_features GLOBAL PROPERTY CMAKE_CXX_KNOWN_FEATURES)
foreach(i ${known_features})
  message("${i}")
endforeach()

Например, эта программа на С++ с именем файла main.cc использует возможности С++ 11: cxx_strong_enums, cxx_constexpr, cxx_auto_type

#include <cstdlib>

int main(int argc, char *argv[]) {
  enum class Color { Red, Orange, Yellow, Green, Blue, Violet };
  constexpr float a = 3.1415f;
  auto b = a;
  return EXIT_SUCCESS;
}

Этот файл CMakeLists.txt будет создавать его

cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
project(foobar CXX)
add_executable(foobar main.cc)                                                                                                                                                                                                                                                     
set(needed_features
    cxx_strong_enums
    cxx_constexpr
    cxx_auto_type)
target_compile_features(foobar PRIVATE ${needed_features})

Ответ 2

В этот момент у CMake нет удобной формы для поддержки С++ 11. В идеале вы бы указали проект С++ 11 следующим образом:

project(foo CXX11)

в начале вашего CMakeLists.txt. Но тип проекта CXX11 не существует (пока). До тех пор вы можете использовать двухэтапный метод:

• Определите тип и версию компилятора
• Отрегулируйте флаги сборки соответственно.

Например, это то, что я использую для поддержки С++ 11 с помощью Clang и GCC:

# Initialize CXXFLAGS.
set(CMAKE_CXX_FLAGS                "-Wall -std=c++11")
set(CMAKE_CXX_FLAGS_DEBUG          "-O0 -g")
set(CMAKE_CXX_FLAGS_MINSIZEREL     "-Os -DNDEBUG")
set(CMAKE_CXX_FLAGS_RELEASE        "-O4 -DNDEBUG")
set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-O2 -g")

# Compiler-specific C++11 activation.
if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "GNU")
    execute_process(
        COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
    if (NOT (GCC_VERSION VERSION_GREATER 4.7 OR GCC_VERSION VERSION_EQUAL 4.7))
        message(FATAL_ERROR "${PROJECT_NAME} requires g++ 4.7 or greater.")
    endif ()
elseif ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -stdlib=libc++")
else ()
    message(FATAL_ERROR "Your C++ compiler does not support C++11.")
endif ()

Ответ 3

Я нашел этот CMake script, который утверждает, что делает именно то, что вам нужно. Он также может проверять отдельные функции С++ 11. Я не думаю, что он может решить между std=C++0x и std=C++11, хотя.

Ответ 4

На момент написания (pre-GCC 4.8), это может быть нецелесообразно обнаруживать флаги С++ 11 и добавлять их. Это связано с тем, что изменение стандарта (по крайней мере для GCC) прерывает совместимость ABI, что может привести к ошибкам в ссылках.

Следовательно, использование стандарта С++ 11 должно явно указываться с настройкой компилятора во время начальной конфигурации CMake проекта, например,

CXX='g++ -std=c++11' cmake /path/to/source

То есть, использование -std = С++ 11 должно рассматриваться как отдельный компилятор, который не следует смешивать или изменять в проекте.

Ответ 5

Использование:

include(CheckCXXCompilerFlag)
CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
if(COMPILER_SUPPORTS_CXX11)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
elseif(COMPILER_SUPPORTS_CXX0X)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
else()
    message(FATAL_ERROR "Compiler ${CMAKE_CXX_COMPILER} has no C++11 support.")
endif()

Это из включения С++ 11 (С++ 0x) в CMake с небольшими изменениями.

Ответ 6

В CMake 3.1 * правильный простой способ сделать это - использовать свойство CXX_STANDARD для данной цели. Например, приведенный простой пример с использованием auto (с именем main.cpp):

#include <iostream>

int main() {
    auto num = 10;
    std::cout << num << std::endl;
    return 0;
}

Следующий CMakeLists.txt включит поддержку С++ 11:

cmake_minimum_required(VERSION 3.3)
project(Hello CXX)

set(SOURCE_FILES main.cpp)
add_executable(Hello ${SOURCE_FILES})

set_property(TARGET Hello PROPERTY
    CXX_STANDARD 11
    CXX_STANDARD_REQUIRED ON
)

Это добавит любые необходимые флаги, такие как -std=c++11. Обратите внимание, что свойство CXX_STANDARD_REQUIRED предотвратит CXX_STANDARD_REQUIRED стандарта на более раннюю версию.

Правильный, не такой простой способ указать CMAKE_CXX_KNOWN_FEATURES который вы используете, например, cxx_auto_type:

cmake_minimum_required(VERSION 3.3)
project(Hello CXX)

set(SOURCE_FILES main.cpp)
add_executable(Hello ${SOURCE_FILES})
target_compile_features(Hello PRIVATE cxx_auto_type)

_{* Я не пробовал это на CMake 3.1, но убедился, что он работает в CMake 3.3.Документация по 3.1 действительно документирует это, поэтому оно должно работать.}

Ответ 7

Мы создали модуль CMake для обнаружения и поддержки поддержки С++ 11, который вы можете найти здесь:
https://github.com/NitroShare/CXX11-CMake-Macros

Он по-прежнему работает, но мы используем его для ряда проектов Qt, предназначенных для Windows/Linux/Mac. В настоящее время поддерживаются только MSVС++, GCC и Clang.

Пример:

include(CXX11)

check_for_cxx11_compiler(CXX11_COMPILER)

# If a C++11 compiler is available, then set the appropriate flags
if(CXX11_COMPILER)
    enable_cxx11()
endif()