Преобразование XLS в CSV в командной строке

Ответ 1

Откройте "Блокнот", создайте файл XlsToCsv.vbs и вставьте его в:

if WScript.Arguments.Count < 2 Then
    WScript.Echo "Error! Please specify the source path and the destination. Usage: XlsToCsv SourcePath.xls Destination.csv"
    Wscript.Quit
End If
Dim oExcel
Set oExcel = CreateObject("Excel.Application")
Dim oBook
Set oBook = oExcel.Workbooks.Open(Wscript.Arguments.Item(0))
oBook.SaveAs WScript.Arguments.Item(1), 6
oBook.Close False
oExcel.Quit
WScript.Echo "Done"

Затем из командной строки перейдите в папку, в которую вы вложили файл .vbs:

XlsToCsv.vbs [sourcexlsFile].xls [destinationcsvfile].csv

Для этого требуется, чтобы Excel был установлен на компьютере, на котором вы находитесь.

Ответ 2

Немного измененная версия ответа ScottF, которая не требует абсолютных путей к файлу:

if WScript.Arguments.Count < 2 Then
    WScript.Echo "Please specify the source and the destination files. Usage: ExcelToCsv <xls/xlsx source file> <csv destination file>"
    Wscript.Quit
End If

csv_format = 6

Set objFSO = CreateObject("Scripting.FileSystemObject")

src_file = objFSO.GetAbsolutePathName(Wscript.Arguments.Item(0))
dest_file = objFSO.GetAbsolutePathName(WScript.Arguments.Item(1))

Dim oExcel
Set oExcel = CreateObject("Excel.Application")

Dim oBook
Set oBook = oExcel.Workbooks.Open(src_file)

oBook.SaveAs dest_file, csv_format

oBook.Close False
oExcel.Quit

Я переименовал script ExcelToCsv, так как этот script не ограничивается только xls. xlsx Работает отлично, как и следовало ожидать.

Протестировано с помощью Office 2010.

Ответ 3

Как с PowerShell?

Код должен выглядеть так, но не проверен.

$xlCSV = 6
$Excel = New-Object -Com Excel.Application 
$Excel.visible = $False 
$Excel.displayalerts=$False 
$WorkBook = $Excel.Workbooks.Open("YOUDOC.XLS") 
$Workbook.SaveAs("YOURDOC.csv",$xlCSV) 
$Excel.quit()

Вот сообщение, объясняющее, как его использовать

Как использовать Windows PowerShell для автоматизации Microsoft Excel?

Ответ 4

Небольшое расширение на ScottF groovy VB script: этот командный файл будет перебирать файлы .xlsx в каталоге и выгружать их в файлы *.csv:

FOR /f "delims=" %%i IN ('DIR *.xlsx /b') DO ExcelToCSV.vbs "%%i" "%%i.csv"

Примечание. Вы можете изменить расширение .xlsx на .xls и имя script ExcelToCSV на XlsToCsv

Ответ 5

Мне нужно было извлечь несколько cvs из разных листов, поэтому здесь приведена модифицированная версия plang-кода, которая позволяет указать имя рабочего листа.

if WScript.Arguments.Count < 3 Then
    WScript.Echo "Please specify the sheet, the source, the destination files. Usage: ExcelToCsv <sheetName> <xls/xlsx source file> <csv destination file>"
    Wscript.Quit
End If

csv_format = 6

Set objFSO = CreateObject("Scripting.FileSystemObject")

src_file = objFSO.GetAbsolutePathName(Wscript.Arguments.Item(1))
dest_file = objFSO.GetAbsolutePathName(WScript.Arguments.Item(2))

Dim oExcel
Set oExcel = CreateObject("Excel.Application")

Dim oBook
Set oBook = oExcel.Workbooks.Open(src_file)

oBook.Sheets(WScript.Arguments.Item(0)).Select
oBook.SaveAs dest_file, csv_format

oBook.Close False
oExcel.Quit

Ответ 6

Почему бы не написать свой собственный?

Я вижу, что из вашего профиля у вас есть хотя бы некоторые возможности С#/.NET. Я бы создал консольное приложение Windows и использовал бесплатный считыватель Excel для чтения в ваших файлах Excel. Я использовал Excel Data Reader, доступный из CodePlex без каких-либо проблем (одна хорошая вещь: этот читатель не требует установки Excel). Вы можете вызвать консольное приложение из командной строки.

Если вы оказались здесь, и я уверен, что вы получите помощь.

Ответ 7

Вот версия, которая будет обрабатывать несколько файлов, перетаскиваемых из окон. Основываясь на приведенных выше работах

Christian Lemer
plang
ScottF

Откройте "Блокнот", создайте файл XlsToCsv.vbs и вставьте его в:

'* Usage: Drop .xl* files on me to export each sheet as CSV

'* Global Settings and Variables
Dim gSkip
Set args = Wscript.Arguments

For Each sFilename In args
    iErr = ExportExcelFileToCSV(sFilename)
    ' 0 for normal success
    ' 404 for file not found
    ' 10 for file skipped (or user abort if script returns 10)
Next

WScript.Quit(0)

Function ExportExcelFileToCSV(sFilename)
    '* Settings
    Dim oExcel, oFSO, oExcelFile
    Set oExcel = CreateObject("Excel.Application")
    Set oFSO = CreateObject("Scripting.FileSystemObject")
    iCSV_Format = 6

    '* Set Up
    sExtension = oFSO.GetExtensionName(sFilename)
    if sExtension = "" then
        ExportExcelFileToCSV = 404
        Exit Function
    end if
    sTest = Mid(sExtension,1,2) '* first 2 letters of the extension, vb missing a Like operator
    if not (sTest =  "xl") then
        if (PromptForSkip(sFilename,oExcel)) then
            ExportExcelFileToCSV = 10
            Exit Function
        end if
    End If
    sAbsoluteSource = oFSO.GetAbsolutePathName(sFilename)
    sAbsoluteDestination = Replace(sAbsoluteSource,sExtension,"{sheet}.csv")

    '* Do Work
    Set oExcelFile = oExcel.Workbooks.Open(sAbsoluteSource)
    For Each oSheet in oExcelFile.Sheets
        sThisDestination = Replace(sAbsoluteDestination,"{sheet}",oSheet.Name)
        oExcelFile.Sheets(oSheet.Name).Select
        oExcelFile.SaveAs sThisDestination, iCSV_Format
    Next

    '* Take Down
    oExcelFile.Close False
    oExcel.Quit

    ExportExcelFileToCSV = 0
    Exit Function
End Function

Function PromptForSkip(sFilename,oExcel)
    if not (VarType(gSkip) = vbEmpty) then
        PromptForSkip = gSkip
        Exit Function
    end if

    Dim oFSO
    Set oFSO = CreateObject("Scripting.FileSystemObject")

    sPrompt = vbCRLF & _
        "A filename was received that doesn't appear to be an Excel Document." & vbCRLF & _
        "Do you want to skip this and all other unrecognized files?  (Will only prompt this once)" & vbCRLF & _
        "" & vbCRLF & _
        "Yes    - Will skip all further files that don't have a .xl* extension" & vbCRLF & _
        "No     - Will pass the file to excel regardless of extension" & vbCRLF & _
        "Cancel - Abort any further conversions and exit this script" & vbCRLF & _
        "" & vbCRLF & _
        "The unrecognized file was:" & vbCRLF & _
        sFilename & vbCRLF & _
        "" & vbCRLF & _
        "The path returned by the system was:" & vbCRLF & _
        oFSO.GetAbsolutePathName(sFilename) & vbCRLF

    sTitle = "Unrecognized File Type Encountered"

    sResponse =  MsgBox (sPrompt,vbYesNoCancel,sTitle)
    Select Case sResponse
    Case vbYes
        gSkip = True
    Case vbNo
        gSkip = False
    Case vbCancel
        oExcel.Quit
        WScript.Quit(10)    '*  10 Is the error code I use to indicate there was a user abort (1 because wasn't successful, + 0 because the user chose to exit)
    End Select

    PromptForSkip = gSkip
    Exit Function
End Function

Ответ 8

Основываясь на том, что предоставил Jon of All Trades, следующее (~ n) удалило проблему досадного двойного расширения: FOR /f "delims=" %%i IN ('DIR *.xlsx /b') DO ExcelToCSV.vbs "%%i" "%%~ni.csv"

Ответ 9

Там есть поставщик данных OLEDB Excel, встроенный в Windows; вы можете использовать это для "запроса" листа Excel через ADO.NET и записи результатов в файл CSV. Там требуется небольшое количество кодирования, но вам не нужно ничего устанавливать на машине.

Ответ 10

Я попробовал решение ScottF VB и получил его для работы. Однако я хотел преобразовать файл excel в несколько вкладок (workbook) в один файл .csv.

Это не сработало, скопирована только одна вкладка (та, которая выделена, когда я открываю ее через excel).

Кто-нибудь знает о script, который может преобразовать файл excel с несколькими вкладками в один файл .csv?

Ответ 11

Вы можете сделать это с помощью утилиты командной строки Alacon для Alasql. Он работает с Node.js, поэтому вам нужно установить Node.js, а затем Alasql.

Чтобы преобразовать файл Excel в CVS (от TSV), вы можете ввести:

> node alacon "SELECT * INTO CSV('mydata.csv', {headers:true}) FROM XLS('mydata.xls', {headers:true})"

По умолчанию Alasql преобразует данные из "Sheet1", но вы можете изменить его с помощью параметров:

{headers:false, sheetid: 'Sheet2', range: 'A1:C100'}

Alacon поддерживает преобразования типа другого типа (CSV, TSV, TXT, XLSX, XLS) и SQL (см. Руководство пользователя).

Ответ 12

Скотт F ответ - лучшее, что я нашел в Интернете. Я добавил к его коду, чтобы удовлетворить мои потребности. Я добавил:

В поле "Ошибка при повторном следующем" < - для учета отсутствующих файлов xls в моей пакетной обработке вверху. oBook.Application.Columns( "A: J" ). NumberFormat = "@" < - перед линией SaveAs, чтобы убедиться, что мои данные сохранены в формате текста, чтобы сохранить excel от удаления начального нуля и исключая запятые в числовых строках в моих данных, т.е. (от 1200 до 1200). Диапазон столбцов должен быть скорректирован для соответствия вашим элементам (A: J).

Я также удалил Echo "done", чтобы сделать его не интерактивным.

Затем я добавил script в командный файл cmd для обработки автоматических данных ежечасно с помощью задачи.