Heredoc для Windows?

Есть ли способ указать многострочные строки в пакете таким же образом, как heredoc в оболочках unix. Нечто похожее на:

cat <<EOF > out.txt
bla
bla
..
EOF

Идея заключается в создании настраиваемого файла из файла шаблона.

Ответ 1

Не знаю, насколько я знаю.

Ближайшее, что я знаю,

> out.txt (
    @echo.bla
    @echo.bla
    ...
)

(@ запрещает самому командная оболочка печатать выполняемые команды, а echo. позволяет запустить строку с пробелом.)

Ответ 2

Здесь другой подход.

@echo off

:: ######################################################
:: ## Heredoc syntax:                                  ##
:: ## call :heredoc uniqueIDX [>outfile] && goto label ##
:: ## contents                                         ##
:: ## contents                                         ##
:: ## contents                                         ##
:: ## etc.                                             ##
:: ## :label                                           ##
:: ##                                                  ##
:: ## Notes:                                           ##
:: ## Variables to be evaluated within the heredoc     ##
:: ## should be called in the delayed expansion style  ##
:: ## (!var! rather than %var%, for instance).         ##
:: ##                                                  ##
:: ## Literal exclamation marks (!) and carats (^)     ##
:: ## must be escaped with a carat (^).                ##
:: ######################################################



:--------------------------------------------
: calling heredoc with results sent to stdout
:--------------------------------------------

call :heredoc stickman && goto next1

\o/
 | This is the "stickman" heredoc, echoed to stdout.
/ \
:next1



:-----------------------------------------------------------------
: calling heredoc containing vars with results sent to a text file
:-----------------------------------------------------------------

set bodyText=Hello world!
set lipsum=Lorem ipsum dolor sit amet, consectetur adipiscing elit.

call :heredoc html >out.txt && goto next2
<html lang="en">
    <body>
        <h3>!bodyText!</h3>
        <p>!lipsum!</p>
    </body>
</html>

Thus endeth the heredoc.  :)
:next2



echo;
echo Does the redirect to a file work?  Press any key to type out.txt and find out.
echo;

pause>NUL
type out.txt
del out.txt

:: End of main script
goto :EOF

:: ########################################
:: ## Here the heredoc processing code ##
:: ########################################
:heredoc <uniqueIDX>
setlocal enabledelayedexpansion
set go=
for /f "delims=" %%A in ('findstr /n "^" "%~f0"') do (
    set "line=%%A" && set "line=!line:*:=!"
    if defined go (if #!line:~1!==#!go::=! (goto :EOF) else echo(!line!)
    if "!line:~0,13!"=="call :heredoc" (
        for /f "tokens=3 delims=>^ " %%i in ("!line!") do (
            if #%%i==#%1 (
                for /f "tokens=2 delims=&" %%I in ("!line!") do (
                    for /f "tokens=2" %%x in ("%%I") do set "go=%%x"
                )
            )
        )
    )
)
goto :EOF

Пример вывода:

C:\Users\oithelp\Desktop>heredoc

\o/
 | This is the "stickman" heredoc, echoed to stdout.
/ \

Does the redirect to a file work?  Press any key to type out.txt and find out.

<html lang="en">
    <body>
        <h3>Hello world!</h3>
        <p>Lorem ipsum dolor sit amet, consectetur adipiscing elit.</p>
    </body>
</html>

Thus endeth the heredoc.  :)

Ответ 3

Да, очень возможно. ^ - буквальный escape-символ, просто поставьте его перед вашей новой строкой. В этом примере я помещаю дополнительную строку новой строки так, чтобы она была правильно напечатана в файле:

@echo off
echo foo ^

this is ^

a multiline ^

echo > out.txt

Вывод:

E:\>type out.txt
foo
 this is
 a multiline
 echo

E:\>

Ответ 4

@echo off
 for /f "delims=:" %%a in (
     'findstr -n "^___" %0') do set "Line=%%a"

 (for /f "skip=%Line% tokens=* eol=_" %%a in (
       'type %0') do echo(%%a) > out.html
:: out.html
pause
goto: EOF



___DATA___
<!Doctype html>
<html>
  <head>
   title></title>
  </head>
  <body>
    <svg width="900" height="600">
        <text x="230" 
              y="150"
              font-size="100"
              fill="blue"
              stroke="gray"
              stroke-width="1">
                  Hello World              
        </text>
    </svg>
  </body>
</html>

Ответ 5

В DosTips siberia-man опубликовал демонстрацию удивительное поведение ошибочного заявления GOTO в виде (goto) 2>nul. Затем Аачини и Джеб задокументировали некоторые дополнительные интересные открытия о странном поведении. Он в основном ведет себя как EXIT /B, за исключением того, что он позволяет выполнять конкатенированные команды в подпрограмме CALLed в контексте родительского вызывающего.

Вот краткий script, который демонстрирует большинство значимых точек:

@echo off
setlocal enableDelayedExpansion
set "var=Parent Value"
(
  call :test
  echo This and the following line are not executed
  exit /b
)
:break
echo How did I get here^^!^^!^^!^^!
exit /b

:test
setlocal disableDelayedExpansion
set "var=Child Value"
(goto) 2>nul & echo var=!var! & goto :break
echo This line is not executed

:break
echo This line is not executed

- OUTPUT -

var=Parent Value
How did I get here!!!!

Это удивительное поведение позволило мне написать элегантную пакетную эмуляцию здесь документа со многими вариантами, доступными для unix. Я реализовал PrintHere.bat как отдельную утилиту, которую нужно поместить в папку, указанную в вашем PATH. Тогда любая партия script может легко вызвать функцию, чтобы получить здесь функциональность doc.

Вот общий синтаксис использования:

call PrintHere :Label
Here doc text goes here
:Label

Как это может быть достигнуто?... Моя утилита PrintHere использует трюк (goto) 2>nul дважды.

В первый раз я использую (goto) 2>nul для возврата к вызывающему, чтобы я мог получить полный путь к вызывающему script, чтобы PrintHere знал, какой файл читать. Затем я вызываю PrintHere второй раз!
Во второй раз я использую (goto) 2>nul, чтобы вернуть вызывающему и GOTO завершающую метку, чтобы текст здесь не был выполнен.

Примечание. script ниже содержит символ табуляции (0x09) в определении вкладки, непосредственно под меткой :start. Некоторые браузеры могут испытывать трудности при отображении и копировании вкладки. В качестве альтернативы вы можете загрузить PrintHere.bat.txt из моего dropbox и просто переименовать его в PrintHere.bat.

Я изначально разместил PrintHere.bat в DosTips, где вы можете отслеживать будущую разработку.

PrintHere.bat

@echo off & setlocal disableDelayedExpansion & goto :start
::PrintHere.bat version 1.1 by Dave Benham
:::
:::call PrintHere [/E] [/- "TrimList"] :Label ["%~f0"]
:::call PrintHere [/E] [/- "TrimList"] :Label "%~f0" | someCommand & goto :Label
:::PrintHere /?
:::PrintHere /V
:::
:::  PrintHere.bat provides functionality similar to the unix here doc feature.
:::  It prints all content between the CALL PrintHere :Label line and the
:::  terminating :Label. The :Label must be a valid label supported by GOTO, with
:::  the additional constraint that it not contain *. Lines are printed verbatim,
:::  with the following exceptions and limitations:
:::
:::    - Lines are lmited to 1021 bytes long
:::    - Trailing control characters are stripped from each line
:::
:::  The code should look something like the following:
:::
:::     call PrintHere :Label
:::         Spacing    and blank lines are preserved
:::
:::     Special characters like & < > | ^ ! % are printed normally
:::     :Label
:::
:::  If the /E option is used, then variables between exclamation points are
:::  expanded, and ! and ^ literals must be escaped as ^! and ^^. The limitations
:::  are different when /E is used:
:::
:::    - Lines are limited to ~8191 bytes long
:::    - All characters are preserved, except !variables! are expanded and ^! and
:::      ^^ are transformed into ! and ^
:::
:::  Here is an example using /E:
:::
:::     call PrintHere /E :SubstituteExample
:::       Hello !username!^!
:::     :SubstituteExample
:::
:::  If the /- "TrimList" option is used, then leading "TrimList" characters
:::  are trimmed from the output. The trim characters are case sensitive, and
:::  cannot include a quote. If "TrimList" includes a space, then it must
:::  be the last character in the list.
:::
:::  Multiple PrintHere blocks may be defined within one script, but each
:::  :Label must be unique within the file.
:::
:::  PrintHere must not be used within a parenthesized code block.
:::
:::  Scripts that use PrintHere must use \r\n for line termination, and all lines
:::  output by PrintHere will be terminated by \r\n.
:::
:::  All redirection associated with a PrintHere must appear at the end of the
:::  command. Also, the CALL can include path information:
:::
:::     call "c:\utilities\PrintHere.bat" :MyBlock>test.txt
:::       This line is written to test.txt
:::     :MyBlock
:::
:::  PrintHere may be used with a pipe, but only on the left side, and only
:::  if the source script is included as a 2nd argument, and the right side must
:::  explicitly and unconditionally GOTO the terminating :Label.
:::
:::     call PrintHere :PipedBlock "%~f0" | more & goto :PipedBlock
:::       text goes here
:::     :PipedBlock
:::
:::  Commands concatenated after PrintHere are ignored. For example:
:::
:::     call PrintHere :ignoreConcatenatedCommands & echo This ECHO is ignored
:::       text goes here
:::     :ignoreConcatenatedCommands
:::
:::  PrintHere uses FINDSTR to locate the text block by looking for the
:::  CALL PRINTHERE :LABEL line. The search string length is severely limited
:::  on XP. To minimize the risk of PrintHere failure when running on XP, it is
:::  recommended that PrintHere.bat be placed in a folder included within PATH
:::  so that the utility can be called without path information.
:::
:::  PrintHere /? prints out this documentation.
:::
:::  PrintHere /V prints out the version information
:::
:::  PrintHere.bat was written by Dave Benham. Devlopment history may be traced at:
:::    http://www.dostips.com/forum/viewtopic.php?f=3&t=6537
:::

:start
set "tab=   "   NOTE: This value must be a single tab (0x09), not one or more spaces
set "sp=[ %tab%=,;]"
set "sp+=%sp%%sp%*"
set "opt="
set "/E="
set "/-="

:getOptions
if "%~1" equ "" call :exitErr Invalid call to PrintHere - Missing :Label argument
if "%~1" equ "/?" (
  for /f "tokens=* delims=:" %%L in ('findstr "^:::" "%~f0"') do echo(%%L
  exit /b 0
)
if /i "%~1" equ "/V" (
  for /f "tokens=* delims=:" %%L in ('findstr /rc:"^::PrintHere\.bat version" "%~f0"') do echo(%%L
  exit /b 0
)
if /i %1 equ /E (
  set "/E=1"
  set "opt=%sp+%.*"
  shift /1
  goto :getOptions
)
if /i %1 equ /- (
  set "/-=%~2"
  set "opt=%sp+%.*"
  shift /1
  shift /1
  goto :getOptions
)
echo %1|findstr "^:[^:]" >nul || call :exitErr Invalid PrintHere :Label
if "%~2" equ "" (
  (goto) 2>nul
  setlocal enableDelayedExpansion
  if "!!" equ "" (
    endlocal
    call %0 %* "%%~f0"
  ) else (
    >&2 echo ERROR: PrintHere must be used within a batch script.
    (call)
  )
)
set ^"call=%0^"
set ^"label=%1^"
set "src=%~2"
setlocal enableDelayedExpansion
set "call=!call:\=[\\]!"
set "label=!label:\=[\\]!"
for %%C in (. [ $ ^^ ^") do (
  set "call=!call:%%C=\%%C!"
  set "label=!label:%%C=\%%C!"
)
set "search=!sp!*call!sp+!!call!!opt!!sp+!!label!"
set "cnt="
for /f "delims=:" %%N in ('findstr /brinc:"!search!$" /c:"!search![<>|&!sp:~1!" "!src!"') do if not defined skip set "skip=%%N"
if not defined skip call :exitErr Unable to locate CALL PrintHere %1
for /f "delims=:" %%N in ('findstr /brinc:"!sp!*!label!$" /c:"!sp!*!label!!sp!" "!src!"') do if %%N gtr %skip% if not defined cnt set /a cnt=%%N-skip-1
if not defined cnt call :exitErr PrintHere end label %1 not found
if defined /E (
  for /f "skip=%skip% delims=" %%L in ('findstr /n "^^" "!src!"') do (
    if !cnt! leq 0 goto :break
    set "ln=%%L"
    if not defined /- (echo(!ln:*:=!) else for /f "tokens=1* delims=%/-%" %%A in (^""%/-%!ln:*:=!") do (
      setlocal disableDelayedExpansion
      echo(%%B
      endlocal
    )
    set /a cnt-=1
  )
) else (
  for /l %%N in (1 1 %skip%) do set /p "ln="
  for /l %%N in (1 1 %cnt%) do (
    set "ln="
    set /p "ln="
    if not defined /- (echo(!ln!) else for /f "tokens=1* delims=%/-%" %%A in (^""%/-%!ln!") do (
      setlocal disableDelayedExpansion
      echo(%%B
      endlocal
    )
  )
) <"!src!"
:break
(goto) 2>nul & goto %~1


:exitErr
>&2 echo ERROR: %*
(goto) 2>nul & exit /b 1

Полная документация встроена в script. Ниже приведены некоторые примеры использования:

Вербальный вывод

@echo off
call PrintHere :verbatim
    Hello !username!^!
    It is !time! on !date!.
:verbatim

- OUTPUT -

    Hello !username!^!
    It is !time! on !date!.

Развернуть переменные (отсроченное расширение не обязательно должно быть включено)

@echo off
call PrintHere /E :Expand
    Hello !username!^!
    It is !time! on !date!.
:Expand

- ВЫВОД -

    Hello Dave!
    It is 20:08:15.35 on Fri 07/03/2015.

Разверните переменные и обрезайте ведущие пробелы

@echo off
call PrintHere /E /- " " :Expand
    Hello !username!^!
    It is !time! on !date!.
:Expand

- ВЫВОД -

Hello Dave!
It is 20:10:46.09 on Fri 07/03/2015.

Вывод может быть перенаправлен в файл

@echo off
call PrintHere :label >helloWorld.bat
  @echo Hello world!
:label

Выход не может быть перенаправлен как вход, но он может быть подключен к сети! К сожалению, синтаксис не так изящен, потому что обе стороны канала выполняются в новом процессе CMD.EXE, поэтому (goto) 2>nul возвращается к дочернему процессу cmd, а не мастер script.

@echo off
call PrintHere :label "%~f0" | findstr "^" & goto :label
  Text content goes here
:label

Ответ 6

Использование макроса с параметрами позволяет написать "heredoc" более простым способом:

@echo off

rem Definition of heredoc macro
setlocal DisableDelayedExpansion
set LF=^


::Above 2 blank lines are required - do not remove
set ^"\n=^^^%LF%%LF%^%LF%%LF%^^"
set heredoc=for %%n in (1 2) do if %%n==2 (%\n%
       for /F "tokens=1,2" %%a in ("!argv!") do (%\n%
          if "%%b" equ "" (call :heredoc %%a) else call :heredoc %%a^>%%b%\n%
          endlocal ^& goto %%a%\n%
       )%\n%
    ) else setlocal EnableDelayedExpansion ^& set argv=


rem Heredoc syntax:
rem
rem %%heredoc%% :uniqueLabel [outfile]
rem contents
rem contents
rem ...
rem :uniqueLabel
rem
rem Same notes of rojo answer apply

rem Example borrowed from rojo answer:

set bodyText=Hello world!
set lipsum=Lorem ipsum dolor sit amet, consectetur adipiscing elit.

%heredoc% :endHtml out.txt
<html lang="en">
    <body>
        <h3>!bodyText!</h3>
        <p>!lipsum!</p>
    </body>
</html>
:endHtml

echo File created:
type out.txt
del out.txt
goto :EOF


rem Definition of heredoc subroutine

:heredoc label
set "skip="
for /F "delims=:" %%a in ('findstr /N "%1" "%~F0"') do (
   if not defined skip (set skip=%%a) else set /A lines=%%a-skip-1
)
for /F "skip=%skip% delims=" %%a in ('findstr /N "^" "%~F0"') do (
   set "line=%%a"
   echo(!line:*:=!
   set /A lines-=1
   if !lines! == 0 exit /B
)
exit /B

Ответ 7

@jeb

setlocal EnableDelayedExpansion
set LF=^


REM Two empty lines are required

другой вариант:

@echo off

:)
setlocal enabledelayedexpansion
>nul,(pause&set /p LF=&pause&set /p LF=)<%0
set LF=!LF:~0,1!

echo 1!LF!2!LF!3

pause

Ответ 8

Ссылаясь на сообщение rojo в fooobar.com/questions/28435/...

Определенно, его решение - это то, что я ищу за несколько раз (конечно, я мог бы попытаться реализовать что-то похожее на это, но лень движется вперед:)). Одна вещь, которую я хотел бы добавить, - незначительное улучшение исходного кода. Я думал, что было бы лучше, если бы перенаправление на файл было написано в конце строки. В этом случае стартовая линия heredoc может быть более строгой и ее анализ проще.

@echo off

set "hello=Hello world!"
set "lorem=Lorem ipsum dolor sit amet, consectetur adipiscing elit."

call :heredoc HTML & goto :HTML
<html>
<title>!hello!</title>
<body>
<p>Variables in heredoc should be surrounded by the exclamation mark (^!).</p>
<p>!lorem!</p>
<p>Exclamation mark (^!) and caret (^^) MUST be escaped with a caret (^^).</p>
</body>
</html>
:HTML

goto :EOF

:: /questions/28435/heredoc-for-windows-batch/208449#208449
:heredoc LABEL
setlocal enabledelayedexpansion
set go=
for /f "delims=" %%A in ( '
    findstr /n "^" "%~f0"
' ) do (
    set "line=%%A"
    set "line=!line:*:=!"

    if defined go (
        if /i "!line!" == "!go!" goto :EOF
        echo:!line!
    ) else (
        rem delims are ( ) > & | TAB , ; = SPACE
        for /f "tokens=1-3 delims=()>&| ,;= " %%i in ( "!line!" ) do (
            if /i "%%i %%j %%k" == "call :heredoc %1" (
                set "go=%%k"
                if not "!go:~0,1!" == ":" set "go=:!go!"
            )
        )
    )
)
goto :EOF

Что я предлагаю по этому коду? Пусть рассмотрим.

Код Rojo очень строгий:

не допускает более одного пробела char в строке между call и :heredoc
call :heredoc является липкой к краю строки (никаких пробелов, разрешенных в начале строки)
перенаправление на файл разрешено где-то внутри строки (не очень полезно) -

Вещи, которые я предлагаю:

менее строгий (более одного пробела в качестве разделителей)
перенаправление в файл разрешено только в конце строки (закругленные скобки разрешены и необходимы)
липкий код к краю строки

Обновление 1: Улучшения для проверки и выполнения начала heredoc:

важная команда - это только call :heredoc LABEL или call :heredoc :LABEL. Поэтому после печати содержимого heredoc можно перейти на другую метку, конец script или запустить exit /b.
удалена неиспользуемая и ненужная команда goto: next2

Обновление 2:

Разделители для внутреннего for равны ( ) > & | TAB , ; = SPACE
Коммутатор /I добавлен в if

Обновление 3:

По следующей ссылке вы можете найти полную версию автономного script (встраивание в ваши скрипты доступно) https://github.com/ildar-shaimordanov/tea-set/blob/master/bin/heredoc.bat

Ответ 9

Вы можете создать цитируемый блок текста с циклом FOR/F, поэтому вам не нужно было бежать от специальных символов, таких как <>|& только %. Это иногда полезно, например, создание html-вывода.

@echo off
setlocal EnableDelayedExpansion
set LF=^


REM Two empty lines are required
set ^"NL=^^^%LF%%LF%^%LF%%LF%^^"

for /F "tokens=* delims=_" %%a in (^"%NL%
___"One<>&|"%NL%
___"two 100%%"%NL%
___%NL%
___"three "quoted" "%NL%
___"four"%NL%
") DO (
   @echo(%%~a
)

Выход

One<>&|
two 100%

three "quoted"
four

Я пытаюсь объяснить код. Переменная LF содержит один символ новой строки, переменная NL содержит ^<LF><LF>^.
Это можно использовать с процентом расширения для размещения ОДНОГО символа новой строки и одной каретки на конце строки.

Обычно FOR/F разделяет цитируемый текст на несколько токенов, но только один раз.
Когда я вставляю символы новой строки, FOR-loop также разбивается на несколько строк.
Цитата в первой и последней строках состоит только в том, чтобы создать правильный синтаксис для цикла FOR.

В начале любой строки _, поскольку первый символ будет экранирован из многострочной каретки предыдущей строки, и если котировка является первым символом, она теряет способность к побегу.
Используются теги _, поскольку пробелы или запятые вызывают проблемы с XP (Else XP-Bug spurious пытается получить доступ к файлам мусора).

Каретка на конце строки также относится только к XP-Bug.

XP-Bug вступает в силу, когда цитируемый текст содержит символы без кавычек ,;=<space>

for /f "tokens=*" %%a in ("a","b","c") do echo %%a

Ответ 10

@echo off
cls
title Drop Bomb
echo/
echo/ creating...
::                                   Creating a batchfile from within a batchfile.
echo @echo off > boom.bat
echo cls      >> boom.bat
echo color F0 >> boom.bat
echo echo/    >> boom.bat
echo echo --- B-O-O-M !!! --- >> boom.bat
echo echo/    >> boom.bat
echo pause    >> boom.bat
echo exit     >> boom.bat
::                                     Now lets set it off
start boom.bat
title That hurt my ears.
cls
echo/
echo - now look what you've done!
pause

Ответ 11

Расширяясь на эфемерном посту, который я считаю лучшим, следующее будет делать:

(
    @echo.line1
    @echo.line2 %time% %os%
    @echo.
    @echo.line4
) | more

В эфемерном посте он перенаправлял в начале, что является приятным стилем, но вы также можете перенаправить в конце как таковой:

(
    @echo.line1
    @echo.line2 %time% %os%
    @echo.
    @echo.line4
) >C:\Temp\test.txt

Обратите внимание, что "@echo." никогда не включается в выход и "@echo". сам по себе дает пустую строку.

Ответ 12

В make файле Microsoft NMake можно использовать true UNIX heredocs, так как владелец потока запросил их. Например, это явное правило для создания файла Deploy.sed:

Deploy.sed:
    type << >[email protected]
; -*-ini-generic-*-
;
; Deploy.sed -- Self-Extracting Directives
;

[Version]
Class=IEXPRESS
SEDVersion=3
    .
    .
[Strings]
InstallPrompt=Install $(NAME)-$(VERSION).xll to your personal XLSTART directory?
DisplayLicense=H:\prj\prog\XLL\$(NAME)\README.txt
    .
    .
<<

clean:
    -erase /Q Deploy.sed

где < расширяется во временное имя файла. NMake создает "на лету" при выполнении правила. То есть, когда Deploy.sed не существует. Приятно, что переменные NMake также расширены (здесь переменные NAME и VERSION). Сохраните это как makefile. Откройте DOS-поле в каталоге make файла и используйте:

> nmake Deploy.sed

чтобы создать файл, и:

> nmake clean

чтобы удалить его. NMake является частью всех версий Visual Studio С++, включая Express-выпуски.

Ответ 13

Здесь вариант эфемерного отличного решения. Это позволяет вам транслировать несколько строк в другую программу без фактического создания текстового файла и ввода, перенаправляющего его в вашу программу:

(@echo.bla
@echo.bla
) | yourprog.exe

Для быстрого рабочего примера вы можете заменить yourprog.exe на more:

(@echo.bla
@echo.bla
) | more

Вывод:

bla
bla

Ответ 14

То, что требовалось OP, было чем-то очень специфичным (создание текстового файла с выходом), и принятый ответ делает это отлично, но представленное решение плохо работает за пределами этого конкретного контекста. Например, если я хочу передать многострочный ввод в команду, я не могу использовать синтаксис ( echo ). Вот что заработало для меня.

Учитывая perl script с именем "echolines.pl", состоящий из следующего (для имитации "реальной" программы):

use strict;
use warnings;

while (<>) {
        chomp;
        print qq(<$_>\n);
}

и командный файл с именем "testme.bat", содержащий:

@echo off

set FOO=foo
set BAR=bar
set BAZ=baz

echo %FOO%^
&echo %BAR%^
&echo %BAZ%|perl echolines.pl

работает, он выдает ожидаемый результат:

C:\>testme
<foo>
<bar>
<baz>

Уход с пробелами должен быть сделан, чтобы гарантировать, что все работает правильно, без пробелов. В частности: каждый конец строки должен быть кареткой (^), за которой следует новая строка, последующие строки должны начинаться немедленно с амперсанда (&), а в последней строке должен быть канал, начинающийся сразу после последнего отправленного элемента, В противном случае это приведет к отсутствию параметров или дополнительных пробелов до и после параметров.

Ответ 15

Попробуйте этот код. (JScript-код внизу записывает "out.html" на диск)

@if(0)==(0) echo on
cscript.exe //nologo //E:JScript "%~f0" source1 out.html
start out.html
goto :EOF

[source1]
<!DOCTYPE html>
<html>
  <head>
   title></title>
  </head>
  <body>
    <svg width="900" height="600">
        <text x="230" 
              y="150"
              font-size="100"
              fill="blue"
              stroke="gray"
              stroke-width="1">
                  Hello World              
        </text>
    </svg>
  </body>
</html>
[/source1]

@end

if (WScript.Arguments.length != 2) WScript.Quit();
var tagName = WScript.Arguments(0);
var path    = WScript.Arguments(1);
var startTag = "[" + tagName + "]"
var endTag   = "[/" + tagName + "]"
var fso = new ActiveXObject("Scripting.FileSystemObject");
var file1 = fso.OpenTextFile(WScript.ScriptFullName);
var txt = "";
var found = false;
while (!file1.AtEndOfStream) {
  var line = file1.ReadLine();
  if (!found) {
    if (line.lastIndexOf(startTag, 0) === 0) found = true;
  } else {
    if (line.lastIndexOf(endTag, 0) === 0) break;
    txt += line + "\n";
  }
}
file1.Close();
var file2 = fso.CreateTextFile(path, true, false);
file2.Write(txt);
file2.Close();

Ответ 16

Вот мой рабочий пример для Oracle NoSQL SQL Shell


    C:>java -jar C:\kv-4.4.6\lib\sql.jar -helper-hosts localhost:5000 -store kvstore ^"select * from TableName"
    {"id":1,"name":"Ridone"}
    {"id":2,"name":"Korkmaz"}
    {"id":3,"name":"Melike"}
    3 rows returned
    C:\Windows\System32>

Ответ 17

В крайнем случае я использую следующий метод (который не уменьшает никаких других методов, это всего лишь личное предпочтение):

Я использую цикл for для набора строк:

for %%l in (
    "This is my"
    "multi-line here document"
    "that this batch file"
    "will print!"
    ) do echo.%%~l >> here.txt

Не требует подпрограммы, ее легко запомнить и выполнить.
Не требует временного файла.
Работает внутри пакетного скрипта.
Работает со встроенными переменными.
Однако: если в ваших строках есть двойные кавычки, метод больше не работает...

Вот еще один практический пример из сценария, над которым я сейчас работаю:

:intc_version:
for %%l in (
    "File         : %_SCRIPT_NAME%"
    "Version      : %_VERSION%"
    "Company      : %_COMPANY%"
    "License      : %_LICENSE%"
    "Description  : %_DESCRIPTION%"
    ""
) do echo.%%~l
exit /B 0

Ответ 18

Это еще проще и близко напоминает cat <EOF> out.txt:

C: \ > copy con out.txt
Это моя первая строка текста.
Это моя последняя строка текста.
^ Z
1 файл скопирован.

Результат выглядит следующим образом:

C: \ > введите out.txt
Это моя первая строка текста.
Это моя последняя строка текста.

(скопируйте con + out.txt, введите свой ввод, затем нажмите Ctrl-Z и файл будет скопирован)

COPY CON означает "копировать с консоли" (принять ввод пользователя)

Ответ 19

C:\>more >file.txt
This is line 1 of file
This is line 2 of file
^C

C:\>type file.txt
This is line 1 of file
This is line 2 of file

** В конце будет добавлена пустая строка, но вы можете легко решить это, просто используя метод копирования con:

C:\>copy con file.txt >nul
This is line 1 of file
This is line 2 of file^Z

C:\>type file.txt
This is line 1 of file
This is line 2 of file

Остерегайтесь, когда вы набираете ^ C и ^ Z в каждом случае.