Пакетная вставка элемента из XML с общим именем файла

Ответ 1

Эта проблема имеет интересный аспект, поэтому я использовал ее для тестирования другого метода обработки файлов.

@echo off
setlocal EnableDelayedExpansion

rem Process all .xml files in current directory
for %%a in (*.xml) do (

   rem Locate the line numbers where "CHANGETIME" and "/ENTRIES" appears
   set "insertLine="
   for /F "delims=:" %%b in ('findstr /N "CHANGETIME /ENTRIES" "%%a"') do (
      if not defined insertLine (
         set "insertLine=%%b"
      ) else (
         set "lastLine=%%b"
      )
   )

   rem Block used to read-input-file/create-output-file
   < "%%a" (

           rem Read the first line from input file
           set /P "line="

           rem Copy lines up to the insertion point
           for /L %%i in (1,1,!insertLine!) do set /P "line=!line!" & echo/

           rem Insert the corresponding REMARK file
           type "RemarksFolder\%%a"

           rem Copy the rest of lines
           set /A insertLine+=1
           for /L %%i in (!insertLine!,1,!lastLine!) do set /P "line=!line!" & echo/

           ) > "output.tmp"
   rem Block-end

   rem Replace input file with created output file
   move /Y "output.tmp" "%%a" > NUL

)

Эта программа должна работать быстрее, чем другие методы, которые сравниваются по строкам; однако недостатком является то, что ведущие пробелы удаляются со всех строк. Хотя дополнительный код может быть вставлен, чтобы исправить этот момент, выполнение этого замедлит процесс...

Ответ 2

Пакетная среда не очень сильно подходит для управления XML как XML. Вероятно, существует способ использования Windows Script Host (VBScript или JScript) для оценки XML DOM, но в этой ситуации, вероятно, проще просто использовать циклы for и echo s.

Прочтите замечания в следующем примере Script для полного объяснения того, как это работает.

@echo off
setlocal

set "remarkDir=remarks\"
set "xmlDir=xml\"

rem // for all files in xmlDir\*.xml
for %%I in ("%xmlDir%\*.xml") do (

    rem // echo filename without line break...
    set /P "=Processing %%~nxI... "<NUL

    rem // Read corresponding remark file into variable
    set /P "remark=" <"%remarkDir%\%%~nxI"

    rem // for each line in xmlDir\file.xml
    for /f "usebackq delims=" %%X in ("%%~fI") do (

        rem // append the line to a new file
        >>"%%~dpnI.new" echo/%%X

        rem // check whether the line contains /CHANGETIME
        set "line=%%X"
        setlocal enabledelayedexpansion
        if not "%%X"=="!line:/CHANGETIME=!" (

            rem // Line contains /CHANGETIME.  Append remark.
            >>"%%~dpnI.new" echo/!remark!
        )
        endlocal

    )

    rem // End of xml file.  Replace old with new.
    move /y "%%~dpnI.new" "%%~fI" >NUL
    echo Done.
)

note: StackOverflow не предназначен для бесплатной службы кодирования, но я сочувствую вам. Похоже, вы приложили много усилий, чтобы покрасить себя в этот уголок. Поэтому я надеюсь, что это поможет вам.

Ответ 3

Простите. В моем первом ответе я сказал, что хочу использовать эту проблему в качестве теста, потому что это интересный аспект. Некоторое время назад я написал вспомогательную программу FilePointer.exe, которая позволяет перемещать указатель файла перенаправленного файла через стандартный дескриптор. Эта программа может быть использована для решения этой проблемы очень простым способом (а также любой другой проблемой с подобной структурой), поскольку прежний метод копирования нескольких строк с помощью команды FOR может быть изменен путем перемещения прямого указателя файла к определенной позиции файла, или простой командой FINDSTR для копирования остальных строк. Вот он:

@echo off
setlocal EnableDelayedExpansion

rem Example of use of FilePointer.exe auxiliary program
rem Antonio Perez Ayala

rem Process all .xml files in current directory
for %%a in (*.xml) do (

   rem Locate the insertion offset where "FILESIZE" line starts
   for /F "delims=:" %%b in ('findstr /O "FILESIZE" "%%a"') do set "insertPoint=%%b"

   rem Block used to edit the file via redirected Stdin and Stdout
   < "%%a" (

      rem Set Stdin file pointer at the insertion point
      FilePointer 0 !insertPoint!

      rem Copy the rest of lines to an auxiliary file
      findstr "^" > auxiliary.tmp 

      rem "FIND and MORE works different than FINDSTR."
      rem "FIND and MORE first resets the file position variable and then read the complete file to the EOF,"
      rem "If you use FINDSTR it simply reads the next data from current position, ..."
      rem http://www.dostips.com/forum/viewtopic.php?f=3&t=2128&p=9720#p9720

      rem Set Stdout file pointer at the insertion point
      FilePointer 1 !insertPoint!

      rem Insert the corresponding REMARK file
      type "RemarksFolder\%%a"

      rem And add the rest of lines
      type auxiliary.tmp

   ) >> "%%a"
   rem Block-end

)

del auxiliary.tmp

Этот метод имеет несколько преимуществ перед первым. Он работает быстрее, а ведущие пробелы сохраняются. Первая часть файла хранится в том же файле, то есть нет необходимости копировать его во временный файл. В этой задаче необходимо скопировать строки из точки ввода в EOF во временном файле, чтобы освободить место для вставленного текста, но в другой проблеме, которая просто нуждается в замене текста другим размером того же размера, изменение происходит незамедлительно без дальнейшей обработки независимо от размера файла! Если новый текст будет короче исходного, необходимо будет "уплотнить" данные после точки замены, а затем обрезать оставшиеся данные, что может быть сделано с помощью Truncate.exe(еще одна из моих вспомогательных программ).

Вы можете загрузить вспомогательную программу FilePointer.exe из этот сайт.