Gradle Script Чтобы вызвать веб-службу REST без каких-либо сторонних плагинов, любые указатели?

Привет Мне нужно вызвать службу REST как часть buildscript (Gradle) без каких-либо сторонних плагинов, как я могу использовать Groovy для этого?

(Моя первая попытка)

repositories {
    mavenCentral()
}
      dependencies {  
            complie "org.codehaus.groovy.modules.http-builder:http-builder:0.5.2"  
    }  

task hello {
    def http = new HTTPBuilder("http://myserver.com:8983/solr/select?q=*&wt=json")
    http.auth.basic 'username', 'password'
    http.request(GET, JSON ) { req ->
    }
}

Ответ 1

Самый простой способ вызвать REST из groovy без внешних библиотек - это выполнить CURL. Вот пример вызова Artifactory, возврата JSON и его анализа:

import groovy.json.JsonSlurper

task hello {
    def p = ['curl', '-u', '"admin:password"', "\"http://localhost:8081/api/storage/libs-release-local?list&deep=1\""].execute()
    def json = new JsonSlurper().parseText(p.text)
}

Ответ 2

Не можете ли вы просто сделать

new URL( 'http://username:[email protected]:8983/solr/select?q=*&wt=json' ).text

Ответ 3

Это работающие ребята

import java.io.*
import groovyx.net.http.HTTPBuilder
import groovyx.net.http.EncoderRegistry
import static groovyx.net.http.Method.*
import static groovyx.net.http.ContentType.*

buildscript {
    repositories {
        mavenCentral()
    }   
    dependencies {
        classpath 'org.codehaus.groovy.modules.http-builder:http-builder:0.5.2'
    }   
}

task hello {
    def http = new groovyx.net.http.HTTPBuilder("http://local.com:8983/solr/update/json")

    http.request(POST, JSON ) { req ->
        req.body{

        }
        response.success = { resp, reader ->
            println "$resp.statusLine   Respond rec"

        }
    }
}

Ответ 4

Я использую JsonSlurper, он выглядит довольно просто и независим от ОС:

import groovy.json.JsonSlurper

String url = "http://<SONAR_URL>/api/qualitygates/project_status?projectKey=first"
def json = new JsonSlurper().parseText(url.toURL().text)
print json['projectStatus']['status']

Ответ 5

Этот вопрос так хорошо ранжируется поисковыми системами, что я постоянно спотыкаюсь о нем.

Однако, как прокомментировали другие, мне не очень нравится принятый ответ, потому что он основан на завитке.

Итак, вот полный пример без каких-либо предварительных условий (без плагина, без скручивания,...):

import groovy.json.JsonSlurper
import groovy.json.JsonOutput
task getExample {
    doLast {
        def req = new URL('https://jsonplaceholder.typicode.com/posts/1').openConnection()
        logger.quiet "Status code: ${req.getResponseCode()}"
        def resp = new JsonSlurper().parseText(req.getInputStream().getText())
        logger.quiet "Response: ${resp}"
    }
}
task postExample {
    doLast {
        def body = [title: "foo", body: "bar", userId: 1]
        def req = new URL('https://jsonplaceholder.typicode.com/posts').openConnection()
        req.setRequestMethod("POST")
        req.setRequestProperty("Content-Type", "application/json; charset=UTF-8")
        req.setDoOutput(true)
        req.getOutputStream().write(JsonOutput.toJson(body).getBytes("UTF-8"))
        logger.quiet "Status code: ${req.getResponseCode()}" // HTTP request done one first read
        def resp = new JsonSlurper().parseText(req.getInputStream().getText())
        logger.quiet "Response: ${resp}"
    }
}

Вы можете запустить это на своем компьютере, так как они используют общедоступный API для разработки.