Haskell полиморфизм и списки

Ответ 1

Если вам действительно нужно это сделать, используйте existential:

{-# LANGUAGE GADTs #-}


class IsShape a where
    draw :: a -> IO ()

data Rectangle = Rectangle Int Int

instance IsShape Rectangle where
    draw (Rectangle length width) = ...

data Circle = Circle Int Int

instance IsShape Circle where
    draw (Circle center radius) = ...

data Shape where
    Shape :: IsShape a => a -> Shape

shapes = [Shape (Circle 5 10), Shape (Circle 20 30), Shape (Rectangle 10 15)]

(Я переименовал ваш класс, так как в противном случае было бы столкновение имен с типом данных, а присвоение имени таким образом кажется более естественным).

Преимущество этого решения над другим ответом, связанным с одним типом данных с разными конструкторами, заключается в том, что он открыт; вы можете определить новые экземпляры IsShape везде, где хотите. Преимущество другого ответа состоит в том, что он более "функциональный", а также что закрытость может в некоторых случаях быть преимуществом, поскольку это означает, что клиенты точно знают, чего ожидать.

Ответ 2

Рассмотрим использование одного типа вместо отдельных типов и класса.

data Shape = Rectangle Int Int
           | Circle Int Int

draw (Rectangle length width) = ...
draw (Circle center radius)   = ...

shapes = [Circle 5 10, Circle 20 30, Rectangle 10 15]

Ответ 3

Как сказал Ганеш, вы действительно можете использовать GADT для обеспечения большей безопасности типов. Но если вы не хотите (или нуждаетесь), здесь я беру на себя следующее:

Как вы уже знаете, все элементы списка должны быть одного типа. Не очень полезно иметь список элементов разных типов, потому что тогда вы выбрасываете информацию о вашем типе.

В этом случае, однако, поскольку вы хотите выбросить информацию о типе (вас просто интересует вытачиваемая часть значения), вы бы предложили изменить тип своих значений на то, что просто доступно.

type Drawable = IO ()

shapes :: [Drawable]
shapes = [draw (Circle 5 10), draw (Circle 20 30), draw (Rectangle 10 15)]

Предположительно, ваш фактический Drawable будет чем-то более интересным, чем просто IO () (может быть, что-то вроде: MaxWidth -> IO ()).

А также из-за ленивой оценки фактическое значение не будет нарисовано, пока вы не закроете список чем-то вроде sequence_. Поэтому вам не нужно беспокоиться о побочных эффектах (но вы, вероятно, уже видели это по типу shapes).

Просто чтобы быть полным (и включить мой комментарий в этот ответ): Это более общая реализация, полезная, если Shape имеет больше функций:

type MaxWith = Int

class Shape a where
    draw :: a -> MaxWidth -> IO ()
    size :: a -> Int

type ShapeResult = (MaxWidth -> IO (), Int)

shape :: (Shape a) => a -> ShapeResult
shape x = (draw x, size x)

shapes :: [ShapeResult]
shapes = [shape (Circle 5 10), shape (Circle 20 30), shape (Rectangle 10 15)]

Здесь функция Shape преобразует значение Shape a в значение ShapeResult, просто вызывая все функции класса Shape. Из-за лени, ни одно из значений фактически не вычисляется до тех пор, пока они вам не понадобятся.

Если честно, я не думаю, что я бы использовал такую ​​конструкцию. Я либо использовал бы метод Drawable сверху, либо если требуется более общее решение, используйте GADT. Это, как говорится, это забавное упражнение.

Ответ 4

Один способ сделать это будет с vtables:

data Shape = Shape {
  draw :: IO (),
  etc :: ...
}

rectangle :: Int -> Int -> Shape
rectangle len width = Shape {
  draw = ...,
  etc = ...
}

circle :: Int -> Int -> Shape
circle center radius = Shape {
  draw = ...,
  etc = ...
}

Ответ 5

Как работать с гетерогенным списком фигур в Haskell - Абстрактный полиморфизм с типами классов:  http://pastebin.com/hL9ME7qP через @pastebin

CODE:

{-# LANGUAGE GADTs #-}

class Shape s where
 area :: s -> Double
 perimeter :: s -> Double

data Rectangle = Rectangle {
 width :: Double,
 height :: Double
} deriving Show

instance Shape Rectangle where
 area rectangle = (width rectangle) * (height rectangle)
 perimeter rectangle = 2 * ((width rectangle) + (height rectangle))

data Circle = Circle {
 radius :: Double
} deriving Show

instance Shape Circle where
 area circle = pi * (radius circle) * (radius circle)
 perimeter circle = 2.0 * pi * (radius circle)

r=Rectangle 10.0 3.0 
c=Circle 10.0
list=[WrapShape r,WrapShape c]

data ShapeWrapper where
 WrapShape :: Shape s => s -> ShapeWrapper

getArea :: ShapeWrapper -> Double
getArea (WrapShape s) = area s

getPerimeter :: ShapeWrapper -> Double
getPerimeter (WrapShape s) = perimeter s

areas = map getArea list
perimeters = map getPerimeter list

Ответ 6

Вариант решения Ганеша с использованием синтаксиса экзистенциальной квантификации.

{-# LANGUAGE ExistentialQuantification #-}
class IsShape a where
    draw :: a -> String

data Rectangle = Rectangle Int Int

instance IsShape Rectangle where
    draw (Rectangle length width) = ""

data Circle = Circle Int Int

instance IsShape Circle where
    draw (Circle center radius) = ""

data Shape = forall a. (IsShape a) => Shape a

shapes = [Shape (Circle 5 10), Shape (Circle 20 30), Shape (Rectangle 10 15)]