Определите, добавляет ли пользователь или удаляет строки

У меня есть макрос VBA, который проверяет введенные пользователем данные (я специально не использовал проверку данных/условное форматирование).

Я использую событие Worksheet_Change для запуска кода, проблема, с которой я сталкиваюсь сейчас, - это когда происходят изменения строки. Я не знаю, является ли это удалением/вставкой строк.

Можно ли различать эти два?

ОТВЕТЫ

Ответ 1

Вы можете определить имя диапазона, например RowMarker =$A$1000

Затем этот код в вашем событии изменения сохранит позицию этого маркера против предыдущей позиции и сообщит о любых изменениях (затем сохранит новую позицию)

Private Sub Worksheet_Change(ByVal Target As Range)
    Static lngRow As Long
    Dim rng1 As Range
    Set rng1 = ThisWorkbook.Names("RowMarker").RefersToRange
    If lngRow = 0 Then
    lngRow = rng1.Row
        Exit Sub
    End If
    If rng1.Row = lngRow Then Exit Sub
    If rng1.Row < lngRow Then
        MsgBox lngRow - rng1.Row & " rows removed"
    Else
        MsgBox rng1.Row - lngRow & " rows added"
    End If
    lngRow = rng1.Row
End Sub

Ответ 2

Предположение. Это означает, что "отличить два" означает отличать добавление/удаление строки от любого другого типа изменения. Если бы вы имели в виду, как определить, было ли изменение добавленной строкой ИЛИ удалять строку, тогда проигнорируйте мой ответ ниже.

В случае вставки или удаления строки, target.cells.count будет всеми ячейками в строке. Таким образом, вы можете использовать этот оператор If для его захвата. Заметьте, что я использую cell.columns.count, поскольку для каждого файла может быть другим. Он также будет срабатывать, если пользователь выберет целую строку и ударит "удалить" (чтобы стереть значения), поэтому вам потребуется код для обхода, хотя...

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)

If Target.Cells.Count = Cells.Columns.Count Then
    MsgBox "Row added or deleted"
End If

End Sub

Ответ 3

Попробуйте этот код:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim lNewRowCount As Long

    ActiveSheet.UsedRange
    lNewRowCount = ActiveSheet.UsedRange.Rows.Count

    If lOldRowCount = lNewRowCount Then
    ElseIf lOldRowCount > lNewRowCount Then
        MsgBox ("Row Deleted")
        lOldRowCount = lNewRowCount
    ElseIf lOldRowCount < lNewRowCount Then
        MsgBox ("Row Inserted")
        lOldRowCount = lNewRowCount
    End If

End Sub

Также добавьте это в модуль ThisWorkBook:

Private Sub Workbook_Open()
    ActiveSheet.UsedRange
    lOldRowCount = ActiveSheet.UsedRange.Rows.Count
End Sub

А потом это в собственном модуле:

Public lOldRowCount As Long

В коде предполагается, что у вас есть данные в строке 1. Обратите внимание, что в первый раз, когда вы его запускаете, вы делаете ложный результат, потому что код должен установить lRowCount в правильную переменную. После этого с этого момента все должно быть хорошо.

Если вы не хотите использовать открытую переменную Public и workheet open, тогда вы можете использовать именованный диапазон на вашем листе где-нибудь и хранить там счетчик строк (lRowCount).

Ответ 4

После поиска бит решил решить его сам. В модуле Worksheet (например, Sheet1 в Microsoft Excel Objects в редакторе VBA) вставьте следующее:

Private usedRowsCount As Long 'use private to limit access to var outside of sheet

'Because select occurs before change we can record the current usable row count
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  usedRowsCount = Target.Worksheet.UsedRange.rows.count 'record current row count for row event detection
End Sub

'once row count recorded at selection we can compare the used row count after change occurs
'with the Target.Address we can also detect which row has been added or removed if you need to do further mods on that row
Private Sub Worksheet_Change(ByVal Target As Range)
  If usedRowsCount < Target.Worksheet.UsedRange.rows.count Then
    Debug.Print "Row Added: ", Target.Address
  ElseIf usedRowsCount > Target.Worksheet.UsedRange.rows.count Then
    Debug.Print "Row deleted: ", Target.Address
  End If
End Sub

Ответ 5

Некоторые из ваших целей назначения различий между вставками и удалениями заканчиваются так, как будет определено, как вы хотите действовать после того, как была идентифицирована вставка или удаление. Возможно, возможно, что сокращение будет существенно сокращено, но я попытался охватить все возможные сценарии.

Private Sub Worksheet_Change(ByVal Target As Range)

    On Error GoTo bm_Safe_Exit
    Application.EnableEvents = False
    Application.ScreenUpdating = False
    Dim olr As Long, nlr As Long, olc As Long, nlc As Long

    With Target.Parent.Cells
        nlc = .Find(what:=Chr(42), after:=.Cells(1), LookIn:=xlValues, lookat:=xlPart, _
                SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
        nlr = .Find(what:=Chr(42), after:=.Cells(1), LookIn:=xlValues, lookat:=xlPart, _
                SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
        Application.Undo    'undo the last change event
        olc = .Find(what:=Chr(42), after:=.Cells(1), LookIn:=xlValues, lookat:=xlPart, _
                SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
        olr = .Find(what:=Chr(42), after:=.Cells(1), LookIn:=xlValues, lookat:=xlPart, _
                SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
        Application.Repeat  'redo the last change event
    End With

    If nlr <> olr Or nlc <> olc Then
        Select Case nlr
            Case olr - 1
                Debug.Print "One (1) row has been deleted"
            Case Is < (olr - 1)
                Debug.Print (olr - nlr) & " rows have been deleted"
            Case olr + 1
                Debug.Print "One (1) row has been inserted"
            Case Is > (olr + 1)
                Debug.Print (nlr - olr) & " rows have been inserted"
            Case olr
                Debug.Print "No rows have been deleted or inserted"
            Case Else
                'don't know what else could happen
        End Select
        Select Case nlc
            Case olc - 1
                Debug.Print "One (1) column has been deleted"
            Case Is < (olc - 1)
                Debug.Print (olc - nlc) & " columns have been deleted"
            Case olc + 1
                Debug.Print "One (1) column has been inserted"
            Case Is > (olc + 1)
                Debug.Print (nlc - olc) & " columns have been inserted"
            Case olc
                Debug.Print "No columns have been deleted or inserted"
            Case Else
                'don't know what else could happen
        End Select
    Else
        'deal with standard Intersect(Target, Range) events here
    End If

bm_Safe_Exit:
    Application.EnableEvents = True
    Application.ScreenUpdating = True

End Sub

По существу, этот код идентифицирует последнюю ячейку по столбцу и последнюю ячейку ячейки по-разному. Затем он отменяет последнюю операцию и снова проверяет. Сравнение двух результатов позволяет определить, была ли строка/столбец вставлена ​​/удалена. После выполнения четырех измерений он переустанавливает последнюю операцию, чтобы можно было обрабатывать любые другие более стандартные операции Worksheet_Change.

Ответ 6

Есть два разных подхода, основанных на следующем шаблоне.

  • Определите переменную модуля или класса модуля типа Range.
  • "Вывод" специального диапазона, назначив его переменной с помощью абсолютного адреса и сохраните ее адрес или размер (это зависит от подхода).
  • Чтобы определить подтип действия пользователя, манипулируйте с переменной в обработчике события изменения листа.

В первом подходе весь диапазон интересов присваивается переменной, а размер диапазона сохраняется. Затем в обработчике событий изменения листа необходимо обработать следующие случаи:

  • возникает исключение при доступе к Address property = > закрепленный диапазон больше не существует;
  • адрес измененной ячейки ниже установленного диапазона = > вставка была = > обновлена ​​переменная
  • новый размер закрепленного диапазона отличается от сохраненного (меньше = > что-то было удалено, больше = > что-то было вставлено).

Во втором подходе к переменной присваивается диапазон "маркер" (см. пример ниже), и адрес диапазона сохраняется для определения движений или сдвигов в любом направлении. Затем в обработчике событий изменения листа необходимо обработать следующие случаи:

  • возникает исключение при доступе к Address property = > диапазон закрепленных маркеров больше не существует;
  • адрес измененной ячейки ниже диапазона "маркер" = > вставка была = > обновлена ​​переменная
  • существует разница в любом направлении, т.е. abs(new_row - saved_row) > 0 or abs(new_col-saved_col) > 0 = > перемещаемый или сдвинутый диапазон.

Плюсы:

  • Пользовательское имя не используется
  • UsedRange свойство не используется
  • Поддерживаемый диапазон обновляется в соответствии с действиями пользователя вместо предположения о том, что действие пользователя не будет происходить ниже 1000-й строки.

Минусы:

  • Переменная должна быть назначена в обработчике событий открытой книги, чтобы использовать ее в обработчике событий изменения листа.
  • Переменная и WithEvents -переменная объекта должны быть привязаны к Nothing в обработчике событий закрытия рабочей книги, чтобы отменить подписку на событие.
  • Невозможно определить операции сортировки из-за изменения значения диапазона вместо строк обмена.

Следующий пример показывает, что оба подхода могут работать. Определить в модуле:

Private m_st As Range
Sub set_m_st()
  Set m_st = [$A$10:$F$10]
End Sub
Sub get_m_st()
  MsgBox m_st.Address
End Sub

Затем запустите set_m_st (просто поместите курсор в суб и вызовите действие Run) в диапазон ввода $A$10:$F$10. Вставьте или удалите строку или ячейку над ней (не путайте с изменением значения ячейки (я)). Запустите get_m_st, чтобы увидеть измененный адрес закрепленного диапазона. Удалите закрепленный диапазон, чтобы получить исключение "Объект" в get_m_st.

Ответ 7

Захват добавления и удаления строк в событии workheet_change.

Я создаю именованный диапазон под названием "CurRowCnt"; формула: = ROWS (таблица 1). Доступ к коду VBA с помощью:

CurRowCnt = Evaluate(Application.Names("CurRowCnt").RefersTo)

Этот именованный диапазон всегда будет содержать количество строк после "строки (строк) вставки или удаления. Я нахожу, что он дает более стабильный CurRowCnt, чем использование глобальной или модульной переменной уровня, лучше для программирования, тестирования и отладки.

Я сохраняю CurRowCnt для свойства настраиваемого документа, снова для целей стабильности.

ThisWorkbook.CustomDocumentProperties("RowCnt").Value = Evaluate(Application.Names("CurRowCnt").RefersTo)

My Worksheet_Change Структура событий выглядит следующим образом:

Dim CurRowCnt as Double
CurRowCnt = Evaluate(Application.Names("CurRowCnt").RefersTo)
Select Case CurRowCnt

    '' ########## ROW(S) ADDED
     Case Is > ThisWorkbook.CustomDocumentProperties("RowCnt").Value
         Dim r As Range
         Dim NewRow as Range

         ThisWorkbook.CustomDocumentProperties("RowCnt").Value = _
         Evaluate(Application.Names("CurRowCnt").RefersTo)

         For Each r In Selection.Rows.EntireRow
             Set NewRow = Intersect(Application.Range("Table1"), r)
             'Process new row(s) here
         next r

    '' ########## ROW(S) DELETED
     Case Is < ThisWorkbook.CustomDocumentProperties("RowCnt").Value

         ThisWorkbook.CustomDocumentProperties("RowCnt").Value = _
         Evaluate(Application.Names("CurRowCnt").RefersTo)

         'Process here

    '' ########## CELL CHANGE
    'Case Is = RowCnt

        'Process here

    '' ########## PROCESSING ERROR
    Case Else 'Should happen only on error with CurRowCnt or RowCnt
        'Error msg here

End Select