Ответ 1

Существуют методы VBA для zip и unzip, используя окна, встроенные в сжатие, которые должны дать некоторое представление о том, как работает система. Вы можете создать эти методы на языке сценариев по вашему выбору.

Основной принцип заключается в том, что в окнах вы можете обрабатывать zip файл как каталог и копировать его и выходить из него. Итак, чтобы создать новый zip файл, вы просто создаете файл с расширением .zip, который имеет правильный заголовок для пустого zip файла. Затем вы закроете его и сообщите окнам, что вы хотите скопировать файлы в него, как если бы это был другой каталог.

Распаковать проще - просто рассматривайте его как каталог.

Если веб-страницы снова потеряны, вот несколько соответствующих фрагментов кода:

ZIP

Sub NewZip(sPath)
'Create empty Zip File
'Changed by keepITcool Dec-12-2005
    If Len(Dir(sPath)) > 0 Then Kill sPath
    Open sPath For Output As #1
    Print #1, Chr$(80) & Chr$(75) & Chr$(5) & Chr$(6) & String(18, 0)
    Close #1
End Sub


Function bIsBookOpen(ByRef szBookName As String) As Boolean
' Rob Bovey
    On Error Resume Next
    bIsBookOpen = Not (Application.Workbooks(szBookName) Is Nothing)
End Function


Function Split97(sStr As Variant, sdelim As String) As Variant
'Tom Ogilvy
    Split97 = Evaluate("{""" & _
                       Application.Substitute(sStr, sdelim, """,""") & """}")
End Function

Sub Zip_File_Or_Files()
    Dim strDate As String, DefPath As String, sFName As String
    Dim oApp As Object, iCtr As Long, I As Integer
    Dim FName, vArr, FileNameZip

    DefPath = Application.DefaultFilePath
    If Right(DefPath, 1) <> "\" Then
        DefPath = DefPath & "\"
    End If

    strDate = Format(Now, " dd-mmm-yy h-mm-ss")
    FileNameZip = DefPath & "MyFilesZip " & strDate & ".zip"

    'Browse to the file(s), use the Ctrl key to select more files
    FName = Application.GetOpenFilename(filefilter:="Excel Files (*.xl*), *.xl*", _
                    MultiSelect:=True, Title:="Select the files you want to zip")
    If IsArray(FName) = False Then
        'do nothing
    Else
        'Create empty Zip File
        NewZip (FileNameZip)
        Set oApp = CreateObject("Shell.Application")
        I = 0
        For iCtr = LBound(FName) To UBound(FName)
            vArr = Split97(FName(iCtr), "\")
            sFName = vArr(UBound(vArr))
            If bIsBookOpen(sFName) Then
                MsgBox "You can't zip a file that is open!" & vbLf & _
                       "Please close it and try again: " & FName(iCtr)
            Else
                'Copy the file to the compressed folder
                I = I + 1
                oApp.Namespace(FileNameZip).CopyHere FName(iCtr)

                'Keep script waiting until Compressing is done
                On Error Resume Next
                Do Until oApp.Namespace(FileNameZip).items.Count = I
                    Application.Wait (Now + TimeValue("0:00:01"))
                Loop
                On Error GoTo 0
            End If
        Next iCtr

        MsgBox "You find the zipfile here: " & FileNameZip
    End If
End Sub

UNZIP

Sub Unzip1()
    Dim FSO As Object
    Dim oApp As Object
    Dim Fname As Variant
    Dim FileNameFolder As Variant
    Dim DefPath As String
    Dim strDate As String

    Fname = Application.GetOpenFilename(filefilter:="Zip Files (*.zip), *.zip", _
                                        MultiSelect:=False)
    If Fname = False Then
        'Do nothing
    Else
        'Root folder for the new folder.
        'You can also use DefPath = "C:\Users\Ron\test\"
        DefPath = Application.DefaultFilePath
        If Right(DefPath, 1) <> "\" Then
            DefPath = DefPath & "\"
        End If

        'Create the folder name
        strDate = Format(Now, " dd-mm-yy h-mm-ss")
        FileNameFolder = DefPath & "MyUnzipFolder " & strDate & "\"

        'Make the normal folder in DefPath
        MkDir FileNameFolder

        'Extract the files into the newly created folder
        Set oApp = CreateObject("Shell.Application")

        oApp.Namespace(FileNameFolder).CopyHere oApp.Namespace(Fname).items

        'If you want to extract only one file you can use this:
        'oApp.Namespace(FileNameFolder).CopyHere _
         'oApp.Namespace(Fname).items.Item("test.txt")

        MsgBox "You find the files here: " & FileNameFolder

        On Error Resume Next
        Set FSO = CreateObject("scripting.filesystemobject")
        FSO.deletefolder Environ("Temp") & "\Temporary Directory*", True
    End If
End Sub

Ответ 2

Да, это может быть сценарий с VBScript. Например, следующий код может создать zip из каталога:

Dim fso, winShell, MyTarget, MySource, file
Set fso = CreateObject("Scripting.FileSystemObject")
Set winShell = createObject("shell.application")


MyTarget = Wscript.Arguments.Item(0)
MySource = Wscript.Arguments.Item(1)

Wscript.Echo "Adding " & MySource & " to " & MyTarget

'create a new clean zip archive
Set file = fso.CreateTextFile(MyTarget, True)
file.write("PK" & chr(5) & chr(6) & string(18,chr(0)))
file.close

winShell.NameSpace(MyTarget).CopyHere winShell.NameSpace(MySource).Items

do until winShell.namespace(MyTarget).items.count = winShell.namespace(MySource).items.count
    wscript.sleep 1000 
loop

Set winShell = Nothing
Set fso = Nothing

Вы также можете найти http://www.naterice.com/blog/template_permalink.asp?id=64, поскольку он включает полную реализацию Unzip/Zip в VBScript.

Если вы выполняете проверку размера каждые 500 мс, а не количество элементов, оно лучше работает для больших файлов. Win 7 мгновенно записывает файл, хотя он не завершил сжатие:

set fso=createobject("scripting.filesystemobject")
Set h=fso.getFile(DestZip)
do
    wscript.sleep 500
    max = h.size
loop while h.size > max 

Отлично работает для огромного количества файлов журнала.

Ответ 3

Просто для ясности: GZip не является алгоритмом только для MS, как предложил Гай Старбак в своем комментарии от августа. GZipStream в System.IO.Compression использует алгоритм Deflate, как и библиотеку zlib, и многие другие инструменты zip. Этот класс полностью совместим с утилитами unix, такими как gzip.

Класс GZipStream не доступен для сценариев из командной строки или VBScript для создания ZIP файлов, поэтому он сам по себе не будет отвечать на исходный запрос плаката.

Свободная библиотека DotNetZip выполняет чтение и создание zip файлов и может быть написана сценарием из VBScript или Powershell. Он также включает инструменты командной строки для создания и чтения/извлечения zip файлов.

Вот код для VBScript:

dim filename 
filename = "C:\temp\ZipFile-created-from-VBScript.zip"

WScript.echo("Instantiating a ZipFile object...")
dim zip 
set zip = CreateObject("Ionic.Zip.ZipFile")

WScript.echo("using AES256 encryption...")
zip.Encryption = 3

WScript.echo("setting the password...")
zip.Password = "Very.Secret.Password!"

WScript.echo("adding a selection of files...")
zip.AddSelectedFiles("*.js")
zip.AddSelectedFiles("*.vbs")

WScript.echo("setting the save name...")
zip.Name = filename

WScript.echo("Saving...")
zip.Save()

WScript.echo("Disposing...")
zip.Dispose()

WScript.echo("Done.")

Вот какой код для Powershell:

[System.Reflection.Assembly]::LoadFrom("c:\\dinoch\\bin\\Ionic.Zip.dll");

$directoryToZip = "c:\\temp";
$zipfile =  new-object Ionic.Zip.ZipFile;
$e= $zipfile.AddEntry("Readme.txt", "This is a zipfile created from within powershell.")
$e= $zipfile.AddDirectory($directoryToZip, "home")
$zipfile.Save("ZipFiles.ps1.out.zip");

В файле .bat или .cmd вы можете использовать инструменты zipit.exe или unzip.exe. Например:

zipit NewZip.zip  -s "This is string content for an entry"  Readme.txt  src 

Ответ 4

Вот моя попытка обобщить встроенные возможности окон для сжатия и сжатия - Как сжать (/zip) и распаковать (/unzip) файлы и папки с помощью пакетного файла без каких-либо внешних инструментов?

с несколькими заданными решениями, которые должны работать почти на всех машинах Windows.

Что касается shell.application и WSH, я предпочел jscript поскольку он позволяет использовать гибридный файл batch/jscript (с расширением .bat), который не требует временных файлов. Я установил unzip и zip-функции в один файл плюс еще несколько функций.

Ответ 5

В пакете UnxUtils, доступном на SourceForge, доступны как zip, так и unzip-исполняемые файлы (а также загрузка лодок других полезных приложений) (http://sourceforge.net/projects/unxutils). Скопируйте их в место в вашем PATH, например "c:\windows", и вы сможете включить их в свои скрипты.

Это не идеальное решение (или тот, который вы просили), но достойный рабочий раунд.

Ответ 6

для создания сжатого архива вы можете использовать утилиту MAKECAB.EXE