Пакетный цикл script

Ответ 1

for /l - ваш друг:

for /l %x in (1, 1, 100) do echo %x

Начинается с 1, шаг за шагом и заканчивается на 100.

Используйте два %, если он в пакетном файле

for /l %%x in (1, 1, 100) do echo %%x

(что является одной из вещей, которые я действительно ненавижу о сценариях Windows)

Если у вас есть несколько команд для каждой итерации цикла, сделайте следующее:

for /l %x in (1, 1, 100) do (
   echo %x
   copy %x.txt z:\whatever\etc
)

или в пакетном файле

for /l %%x in (1, 1, 100) do (
   echo %%x
   copy %%x.txt z:\whatever\etc
)

Key:
/l означает, что команда for будет работать численно, а не работать с набором файлов
%x - переменная циклов
(начальное значение, приращение значения, конечное условие [включительно])

Ответ 2

И для итерации по файлам каталога:

@echo off 
setlocal enableDelayedExpansion 

set MYDIR=C:\something
for /F %%x in ('dir /B/D %MYDIR%') do (
  set FILENAME=%MYDIR%\%%x\log\IL_ERROR.log
  echo ===========================  Search in !FILENAME! ===========================
  c:\utils\grep motiv !FILENAME!
)

Вы должны использовать "enableDelayedExpansion" и! FILENAME! вместо $FILENAME $. Во втором случае DOS интерпретирует переменную только один раз (до того, как она войдет в цикл), а не каждый раз, когда программа петлиет.

Ответ 3

Шаблон для простого, но подсчитанного цикла:

set loopcount=[Number of times]
:loop
[Commands you want to repeat]
set /a loopcount=loopcount-1
if %loopcount%==0 goto exitloop
goto loop
:exitloop

Пример: Скажите "Hello World!" 5 раз:

@echo off
set loopcount=5
:loop
echo Hello World!
set /a loopcount=loopcount-1
if %loopcount%==0 goto exitloop
goto loop
:exitloop
pause

В этом примере выводится:

Hello World!
Hello World!
Hello World!
Hello World!
Hello World!
Press any key to continue . . .

Ответ 4

Или вы можете уменьшать/увеличивать переменную на количество циклов, которые вы хотите выполнить:

SETLOCAL ENABLEDELAYEDEXPANSION
SET counter=200
:Beginning
IF %counter% NEQ 0 (
echo %x
copy %x.txt z:\whatever\etc
SET /A counter=%counter%-1
GOTO Beginning
) ELSE (
ENDLOCAL
SET counter=
GOTO:eof

Очевидно, использование FOR /L - это шоссе, и это задний ход, который занимает больше времени, но он попадает в тот же пункт назначения.

Ответ 5

Вы также можете попробовать это вместо цикла for:

set count=0
:loop
set /a count=%count%+1
(Commands here)
if %count% neq 100 goto loop
(Commands after loop)

Это довольно мало, и это то, что я использую все время.

Ответ 6

Вы можете сделать что-то для следующего эффекта, избегая цикла FOR.

set counter=0
:loop
echo "input commands here"
SET /A counter=%counter%+1
if %counter% GTR 200
(GOTO exit) else (GOTO loop)
:exit
exit

Ответ 7

Вы можете сделать это без инструкции for ^. ^:

@echo off
:SPINNER
SET COUNTP1=1

:1
CLS
 :: YOUR COMMAND GOES HERE
IF !COUNTP1! EQU 200 goto 2

SET COUNTP1=1
) ELSE (
SET /A COUNTP1+=1
)
goto 1

:2
:: COMMAND HAS FINISHED RUNNING 200 TIMES

У этого есть основное понимание. Просто дайте ему тест.: P

Ответ 8

DOS не предлагает очень элегантных механизмов для этого, но я думаю, что вы все равно можете закодировать цикл для 100 или 200 итераций с разумными усилиями. Хотя нет числового цикла for, вы можете использовать символьную строку как "переменную цикла".

Кодируйте цикл с использованием GOTO, и для каждой итерации используйте SET X=%X%@, чтобы добавить еще один знак @ в переменную окружения X; и для выхода из цикла сравните значение X со строкой из 100 (или 200) знаков @.

Я никогда не говорил, что это было изящно, но оно должно работать!

Ответ 9

Очень простой способ реализовать цикл в программировании cmd с использованием меток

@echo off
SET /A "index=1"
SET /A "count=5"
:while
if %index% leq %count% (
   echo The value of index is %index%
   SET /A "index=index + 1"
   goto :while
)

Ответ 10

Не уверен, что такой ответ уже представлен, но вы можете попробовать что-то вроде этого:

@echo off
:start
set /a var+=1
if %var% EQU 100 goto end
:: Code you want to run goes here
goto start

:end
echo var has reached %var%.
pause
exit

Переменная% var% будет увеличиваться на единицу, пока не достигнет 100, где программа затем выведет, что она закончила выполнение. Опять же, не уверен, что это было представлено или что-то в этом роде, но я думаю, что это может быть самым компактным.

Ответ 11

Я использую это. Это примерно то же самое, что и другие, но это просто еще один способ написать его.

@ECHO off
set count=0
:Loop
if %count%==[how many times to loop] goto end
::[Commands to execute here]
set count=%count%+1
goto Loop
:end

Ответ 12

Ответ действительно зависит от того, насколько вы знакомы с партией, если вы не так опытны, я бы рекомендовал увеличивать переменную цикла:

@echo off
set /a loop=1
:repeat
echo Hello World!
set /a loop=%loop%+1
if %loop%==<no. of times to repeat> (
goto escapedfromrepeat
)
goto repeat
:escapedfromrepeat
echo You have come out of the loop
pause

Но если у вас больше опыта с партией, я бы рекомендовал, чтобы более практичный for /l %loop in (1, 1, 10) do echo %loop был лучшим выбором.

             (start at 1, go up in 1's, end at 10)
for /l %[your choice] (start, step, end) do [command of your choice]

Ответ 13

Используйте последовательность для цикла

for i in 'seq 1 100'
do 
   echo $i
done

Ответ 14

(EDITED) Я сделал это, чтобы он остановился через 100 раз

@echo off
goto actual
set /a loopcount=0
:actual
set /a loopcount=%loopcount% + 1
echo %random% %random% %random% %random%
timeout 1 /nobreak>nul
if %loopcount%== 100 goto stop
goto actual
:stop
exit

Это будет генерировать 4 случайных числа за 1 секунду 100 раз. Выньте "тайм-аут 1/nobreak > nul", чтобы сделать его очень быстрым.