Условное короткое замыкание VBScript

У меня есть большое классическое приложение ASP, которое я должен поддерживать, и я неоднократно оказывался в затруднении из-за отсутствия возможности оценки короткого замыкания. Например, VBScript не позволит вам избежать:

if not isNull(Rs("myField")) and Rs("myField") <> 0 then
...

... потому что если Rs ( "myField" ) равно null, вы получите ошибку во втором условии, сравнивая значение null с 0. Поэтому я обычно делаю это вместо:

dim myField
if isNull(Rs("myField")) then 
    myField = 0
else
    myField = Rs("myField")
end if

if myField <> 0 then
...

Очевидно, что многословие довольно ужасно. Оглядываясь вокруг этой большой базы кода, лучшим решением, которое я нашел, является использование функции, которую написал первоначальный программист, называемый TernaryOp, который в основном выполняет трансплантацию в тройных операторских функциях, но я все еще придерживаюсь с использованием временной переменной, которая не будет необходимо на более полнофункциональном языке. Есть ли способ лучше? Какой-то сверхсекретный способ короткого замыкания действительно существует в VBScript?

Ответ 1

Возможно, это не лучший способ, но он, безусловно, работает... Кроме того, если вы находитесь в vb6 или .net, у вас могут быть разные методы, которые также применяются к соответствующему типу.

if cint( getVal( rs("blah"), "" ) )<> 0 then
  'do something
end if


function getVal( v, replacementVal )
  if v is nothing then
    getVal = replacementVal
  else
    getVal = v
  end if
end function

Ответ 2

Вложенные ИФ (только немного менее подробные):

if not isNull(Rs("myField")) Then
   if Rs("myField") <> 0 then

Ответ 3

Я всегда использовал выражения Select Case для логики коротких замыканий в VB. Что-то вроде..

Select Case True

Case isNull(Rs("myField"))

    myField = 0

Case (Rs("myField") <> 0)

    myField = Rs("myField")

Case Else

    myField = -1        

End Select

Мой синтаксис может быть выключен, некоторое время. Если первый случай всплывает, все остальное игнорируется.

Ответ 4

Или, возможно, у меня возник неправильный конец вопроса. Вы имели в виду что-то вроде iIf() в VB? Это работает для меня:

myField = returnIf(isNothing(rs("myField")), 0, rs("myField"))

где returnIf() - такая функция:

function returnIf(uExpression, uTrue, uFalse)
    if (uExpression = true) then returnIf = uTrue else returnIf = uFalse : end if
end function

Ответ 5

Если вы напишете это как два встроенных оператора IF, вы можете добиться короткого замыкания:

if not isNull(Rs("myField")) then if Rs("myField") <> 0 then ...

Но ваше действие then должно появиться в той же строке. Если вам нужно несколько операторов после then, их можно разделить на : или переместить код в подпрограмму, которую вы можете вызвать. Например:

if not isNull(Rs("myField")) then if Rs("myField") <> 0 then x = 1 : y = 2

или

if not isNull(Rs("myField")) then if Rs("myField") <> 0 then DoSomething(Rs("myField"))

Ответ 6

Если бы это было, мой друг - TernaryOp - ваша единственная надежда.

Ответ 7

Да, это не лучшее решение, но мы используем что-то вроде этого

function ReplaceNull(s)
    if IsNull(s) or s = "" then
        ReplaceNull = "&nbsp;"
    else
        ReplaceNull = s
    end if
end function

Ответ 8

Приходят на ум два варианта:

1) используйте len() или lenb(), чтобы узнать, есть ли какие-либо данные в переменной:

if not lenb(rs("myField"))=0 then...

2) используйте функцию, которая возвращает логическое значение:

if not isNothing(rs("myField")) then...

где isNothing() - такая функция:

function isNothing(vInput)
    isNothing = false : vInput = trim(vInput)
    if vartype(vInput)=0 or isEmpty(vInput) or isNull(vInput) or lenb(vInput)=0 then isNothing = true : end if 
end function

Ответ 9

Вы можете просто использовать Else для поиска нулей, "" и т.д.

If UCase(Rs("myField")) = "THING" then
  'Do Things
elseif UCase(Rs("myField")) = "STUFF" then
  'Do Other Stuff
else
  'Invalid data, such as a NULL, "", etc.
  'Throw an error, do nothing, or default action
End If

Я тестировал это в своем коде и сейчас работает. Может быть, не все правильно.