Как получить доступ к HTTP-заголовку запроса в CGI script?

Я использовал Perl для небольших приложений и тестового кода, но я новичок в создании сетей и CGI.

Я получаю, как сделать заголовок запроса (используя CGI.pm и распечатать результаты функции header()), но не смог найти какую-либо информацию о том, как получить доступ к заголовкам, отправленным на мой CGI script. Может ли кто-нибудь указать мне в правильном направлении?

Это может быть вызвано следующим запросом:

curl http://127.0.0.1:80/cgi-bin/headers.cgi -H "HeaderAttribute: value"

Ответ 1

Модуль CGI имеет функцию http(), которую вы можете использовать для этой цели:

#!/usr/bin/perl --
use strict;
use warnings;
use CGI;

my $q = CGI->new;
my %headers = map { $_ => $q->http($_) } $q->http();

print $q->header('text/plain');
print "Got the following headers:\n";
for my $header ( keys %headers ) {
    print "$header: $headers{$header}\n";
}

Попробуйте; приведенное выше дает мне:

$ curl http://localhost/test.cgi -H "HeaderAttribute: value"
Got the following headers:
HTTP_HEADERATTRIBUTE: value
HTTP_ACCEPT: */*
HTTP_HOST: localhost
HTTP_USER_AGENT: curl/7.21.0 (i686-pc-linux-gnu) libcurl/7.21.0 OpenSSL/0.9.8o zlib/1.2.3.4 libidn/1.18

Ответ 2

В дополнение к методу CGI.pm http() вы можете получить информацию заголовков HTTP из переменных среды.

Итак, если вы используете что-то вроде CGI:: Minimal, у которого нет метода http. вы можете сделать что-то вроде:

  my $header = 'HTTP_X_REQUESTED_WITH';

  if (exists $ENV{$header} && lc $ENV{$header} eq 'xmlhttprequest') {
   _do_some_ajaxian_stuff();
  }

Ответ 3

Они поставляются как переменные среды, такие как

HTTP_HEADERATTRIBUTE=value

Возможно, вам придется что-то сделать, чтобы настроить веб-сервер для предоставления такой переменной.