Зависит отпечатки printf в Идрисе

Я пытаюсь перевести на Идриса пример из Cayenne - языка с зависимыми типами .

Вот что я до сих пор:

PrintfType : (List Char) -> Type
PrintfType Nil                = String
PrintfType ('%' :: 'd' :: cs) = Int -> PrintfType cs
PrintfType ('%' :: 's' :: cs) = String -> PrintfType cs
PrintfType ('%' ::  _  :: cs) = PrintfType cs
PrintfType ( _  :: cs)        = PrintfType cs

printf : (fmt: List Char) -> PrintfType fmt
printf fmt = rec fmt "" where
  rec : (f: List Char) -> String -> PrintfType f
  rec Nil acc = acc
  rec ('%' :: 'd' :: cs) acc = \i => rec cs (acc ++ (show i))
  rec ('%' :: 's' :: cs) acc = \s => rec cs (acc ++ s) 
  rec ('%' ::  _  :: cs) acc = rec cs acc  -- this is line 49
  rec ( c  :: cs)        acc = rec cs (acc ++ (pack [c]))

Я использую List Char вместо String для аргумента формата, чтобы облегчить сопоставление с шаблоном, так как я быстро столкнулся с сложностью с сопоставлением шаблонов на String.

К сожалению, я получаю сообщение об ошибке, о котором я не могу понять:

Type checking ./sprintf.idr
sprintf.idr:49:Can't unify PrintfType (Prelude.List.:: '%' (Prelude.List.:: t cs)) with PrintfType cs

Specifically:
    Can't convert PrintfType (Prelude.List.:: '%' (Prelude.List.:: t cs)) with PrintfType cs

Если я прокомментирую все случаи сопоставления шаблонов с 3 элементами (те, что с '%' :: ...) в PrintfType и printf, тогда компиляция кода (но, очевидно, не делает ничего интересного).

Как исправить мой код, чтобы printf "the %s is %d" "answer" 42 работал?

ОТВЕТЫ

Ответ 1

Похоже, что существуют некоторые текущие ограничения в idris при определении функций, где шаблоны перекрываются (например, '%' :: 'd' перекрывается с c :: cs). После многих попыток, Я, наконец, выяснил обходное решение для этого:

data Format = End | FInt Format | FString Format | FChar Char Format
fromList : List Char -> Format
fromList Nil                = End
fromList ('%' :: 'd' :: cs) = FInt    (fromList cs)
fromList ('%' :: 's' :: cs) = FString (fromList cs)
fromList (c :: cs)          = FChar c (fromList cs)

PrintfType : Format -> Type
PrintfType End            = String
PrintfType (FInt rest)    = Int -> PrintfType rest
PrintfType (FString rest) = String -> PrintfType rest
PrintfType (FChar c rest) = PrintfType rest

printf : (fmt: String) -> PrintfType (fromList $ unpack fmt)
printf fmt = printFormat (fromList $ unpack fmt) where
  printFormat : (fmt: Format) -> PrintfType fmt
  printFormat fmt = rec fmt "" where
    rec : (f: Format) -> String -> PrintfType f
    rec End acc            = acc
    rec (FInt rest) acc    = \i: Int => rec rest (acc ++ (show i))
    rec (FString rest) acc = \s: String => rec rest (acc ++ s)
    rec (FChar c rest) acc = rec rest (acc ++ (pack [c]))

Format - это рекурсивный тип данных, представляющий строку формата. FInt является заполнителем int, FString является строковым заполнителем, а FChar является литералом char. Используя Format, я могу определить PrintfType и реализовать printFormat. Оттуда я могу плавно расширить, чтобы взять строку, а не значение List Char или Format. И конечный результат:

*sprintf> printf "the %s is %d" "answer" 42
"the answer is 42" : String