Используйте QuickCheck, генерируя простые числа

Фон

Для удовольствия я пытаюсь написать свойство для быстрой проверки, которое может протестировать основную идею криптографии с RSA.

Для всех x таких, что 1 < x < N, всегда верно, что (x^e)^d = x modulo N

Другими словами, x является "сообщением", поднимая его на e th power mod N, является действием "кодирования" сообщения и повышения кодированного сообщения до d th power mod N - это акт его "декодирования".

(Свойство также тривиально верно для x = 1, случай, который является его собственным шифрованием)

код

Вот методы, которые я кодировал до сих пор:

import Test.QuickCheck

-- modular exponentiation
modExp :: Integral a => a -> a -> a -> a
modExp y z n = modExp' (y `mod` n) z `mod` n
    where modExp' y z | z == 0 = 1
                      | even z =  modExp (y*y) (z `div` 2) n
                      | odd z  = (modExp (y*y) (z `div` 2) n) * y

-- relatively prime
rPrime :: Integral a => a -> a -> Bool
rPrime a b = gcd a b == 1

-- multiplicative inverse (modular)
mInverse :: Integral a => a -> a -> a
mInverse 1 _ = 1
mInverse x y = (n * y + 1) `div` x
    where n = x - mInverse (y `mod` x) x

-- just a quick way to test for primality
n `divides` x = x `mod` n == 0
primes = 2:filter isPrime [3..]
isPrime x = null . filter (`divides` x) $ takeWhile (\y -> y*y <= x) primes

-- the property
prop_rsa (p,q,x) = isPrime p  &&
                   isPrime q  &&
                   p /= q     &&
                   x > 1      &&
                   x < n      &&
                   rPrime e t ==>
                   x == (x `powModN` e) `powModN` d
    where e = 3
          n = p*q
          t = (p-1)*(q-1)
          d = mInverse e t
          a `powModN` b = modExp a b n

(Спасибо, google и случайный блог, для реализация модульного мультипликативного обратного)

Вопрос

Проблема должна быть очевидной: существует слишком много условий для свойства, чтобы сделать его применимым. При попытке вызвать quickCheck prop_rsa в ghci мой терминал зависает.

Итак, я немного покрутил руководство QuickCheck, и он говорит:

Свойства могут иметь вид

forAll <generator> $ \<pattern> -> <property>

Как сделать <generator> для простых чисел? Или с другими ограничениями, так что quickCheck не нужно просеивать кучу неудачных условий?

Приветствуем любые другие общие рекомендации (особенно в отношении QuickCheck).

ОТВЕТЫ

Ответ 1

ОК, вот что я сделал.

Верх файла

{-# LANGUAGE NoMonomorphismRestriction #-}

import Test.QuickCheck
import Control.Applicative

Весь код, заданный в вопросе, за исключением prop_rsa. Это было (очевидно) сильно изменено:

prop_rsa = forAll primePair $ \(p,q) ->
           let n = p*q
           in forAll (genUnder n) $ \x  ->
              let e = 3
                  t = (p-1)*(q-1)
                  d = mInverse e t
                  a `powModN` b = modExp a b n
              in p /= q &&
                 rPrime e t ==>
                 x == (x `powModN` e) `powModN` d

Тип primePair - Gen (Int, Int), а тип для genUnder - Int -> Gen Int. Я не совсем уверен, что за магия стоит forAll, но я уверен, что это правильно. Я сделал некоторые специальные корректировки: 1) убедитесь, что он терпит неудачу, если я испортил условия и 2) убедитесь, что вложенный forAll меняет значение x в тестовых случаях.

Итак, вот как писать эти генераторы. Как только я понял, что <generator> в документации просто означает что-то типа Gen a, это был торт.

genNonzero = (\x -> if x == 0 then 1 else x) `fmap` arbitrary
genUnder :: Int -> Gen Int
genUnder n = ((`mod` n) . abs) `fmap` genNonzero

genSmallPrime = ((\x -> (primes !! (x `mod` 2500))) . abs) `fmap` arbitrary

primePair :: Gen (Int, Int)
primePair = (,) <$> genSmallPrime <*> genSmallPrime

primePair принял несколько проб и ошибок для меня, чтобы получить право; Я знал, что такие комбайнаторы должны работать, но я все еще не так хорошо знаком с fmap, <$> и <*>, каким хотел бы быть. Я ограничил вычисление только выбором из первых 2500 простых чисел; в противном случае, по-видимому, он хотел выбрать некоторые действительно большие, которые потребовались навсегда для создания.

Случайная вещь, чтобы отметить

Благодаря лень, d = mInverse e t не вычисляется, если условия не выполняются. Это хорошо, потому что это undefined, когда условие rPrime e t ложно. На английском языке целое число a имеет только мультипликативный обратный (mod b), когда a и b являются взаимно простыми.

Ответ 2

Здесь один из способов сделать QuickCheck-совместимый генератор простых чисел (кража реализации сита эратосфена из http://en.literateprograms.org/Sieve_of_Eratosthenes_(Haskell)):

import Test.QuickCheck

newtype Prime = Prime Int deriving Show

primes = sieve [2..]
    where
      sieve (p:xs) = Prime p : sieve [x | x <- xs, x `mod` p > 0]

instance Arbitrary Prime where
    arbitrary = do i <- arbitrary
                   return $ primes!!(abs i)

Его можно использовать в QuickCheck следующим образом:

prop_primes_dont_divide (Prime x) (Prime y) = x == y || x `mod` y > 0

Для вашего использования вы замените p и q на (Prime p) и (Prime q) в свойстве.