Правильное использование транзакций в SQL Server

У меня есть 2 команды, и обе они должны быть выполнены правильно, или ни одна из них не выполнена. Поэтому я думаю, что мне нужна транзакция, но я не знаю, как правильно ее использовать.

В чем проблема со следующим скриптом?

BEGIN TRANSACTION [Tran1]

INSERT INTO [Test].[dbo].[T1]
    ([Title], [AVG])
VALUES ('Tidd130', 130), ('Tidd230', 230)

UPDATE [Test].[dbo].[T1]
  SET [Title] = N'az2' ,[AVG] = 1
  WHERE [dbo].[T1].[Title] = N'az'

COMMIT TRANSACTION [Tran1]
GO

Команда INSERT выполнена, но есть проблема с командой UPDATE.

Как я могу реализовать это для отката обеих команд, если какая-либо из них имеет ошибку в выполнении?

Ответ 1

Добавьте блок try/catch, если транзакция завершится успешно, изменения будут зафиксированы, в случае неудачи транзакция откатывается:

BEGIN TRANSACTION [Tran1]

  BEGIN TRY

      INSERT INTO [Test].[dbo].[T1] ([Title], [AVG])
      VALUES ('Tidd130', 130), ('Tidd230', 230)

      UPDATE [Test].[dbo].[T1]
      SET [Title] = N'az2' ,[AVG] = 1
      WHERE [dbo].[T1].[Title] = N'az'

      COMMIT TRANSACTION [Tran1]

  END TRY

  BEGIN CATCH

      ROLLBACK TRANSACTION [Tran1]

  END CATCH

Ответ 2

В начале хранимой процедуры следует поместить SET XACT_ABORT ON, чтобы проинструктировать Sql Server автоматически откат транзакции в случае ошибки. Если ommited или установлен в OFF, вам нужно проверить @@ERROR после каждого заявления или использовать TRY... CATCH rollback.

Ответ 3

Легкий подход:

CREATE TABLE T
(
    C [nvarchar](100) NOT NULL UNIQUE,
);

SET XACT_ABORT ON -- Turns on rollback if T-SQL statement raises a run-time error.
SELECT * FROM T; -- Check before.
BEGIN TRAN
    INSERT INTO T VALUES ('A');
    INSERT INTO T VALUES ('B');
    INSERT INTO T VALUES ('B');
    INSERT INTO T VALUES ('C');
COMMIT TRAN
SELECT * FROM T; -- Check after.
DELETE T;