Простой способ использования API GHC для приложений, развернутых в Windows

Я хочу развернуть приложение в Windows, которому необходимо получить доступ к API GHC. Используя первый простой пример из Wiki:

http://www.haskell.org/haskellwiki/GHC/As_a_library

приводит к следующей ошибке (скомпилированной на одной машине с платформой haskell и выполняемой на другой чистой установке Windows): test.exe: не удается найти базу данных пакета в C:\haskell\lib\package.conf.d

Я хотел бы развернуть свое приложение как простой zip файл и не требовать от пользователя установки. Есть ли простой способ включить необходимые вещи GHC в этот zip файл, чтобы он работал?

ОТВЕТЫ

Ответ 1

Эта программа скопирует необходимые файлы в указанный каталог (будет работать только в окнах):

import Data.List (isSuffixOf)
import System.Environment (getArgs)
import GHC.Paths (libdir)
import System.Directory
import System.FilePath 
import System.Cmd

main = do
  [to] <- getArgs
  let libdir' = to </> "lib"
  createDirectoryIfMissing True libdir'
  copy libdir libdir'
  rawSystem "xcopy"
    [ "/e", "/q"
    , dropFileName libdir </> "mingw"
    , to </> "mingw\\"]


-- | skip some files while copying
uselessFile f
  = or $ map (`isSuffixOf` f)
    [ "."
    , "_debug.a"
    , "_p.a", ".p_hi"    -- libraries built with profiling
    , ".dyn_hi", ".dll"] -- dynamic libraries


copy from to
  = getDirectoryContents from
  >>= mapM_ copy' . filter (not . uselessFile)
  where
    copy' f = do
      let (from', to') = (from </> f, to </> f)
      isDir <- doesDirectoryExist from'
      if isDir
          then createDirectory to' >> copy from' to'
          else copyFile from' to'

После запуска с целевым каталогом в качестве аргумента вы будете иметь локальную копию lib и mingw (всего около 300 Мб).

Вы можете удалить неиспользуемые библиотеки из lib, чтобы сохранить больше места.