Функция Haskell, которая принимает вариационную функцию как аргумент (и возвращает что-то еще, чем эта функция) без FlexibleInstances, чистый Haskell2010

Можно ли выразить следующую программу Haskell без FlexibleInstances, т.е. в чистом Haskell2010?

{-# LANGUAGE FlexibleInstances #-}

class    Funk a       where  truth :: a  -> [Bool]
instance Funk [Bool]  where  truth =  \x ->  x
instance Funk Bool    where  truth =  \x -> [x]

instance Funk b => Funk (Bool -> b) where
    truth f = concat [truth (f True), truth (f False)]

Это вдохновляет ответ на Как написать функцию Haskell, которая принимает вариационную функцию в качестве аргумента.

Я подозреваю, что проблема заключается в том, что truth возвращает что-то другое, чем функция, которую он принимает в качестве аргумента (который возвращает Bool, а не [Bool]).

Цель этого фрагмента состоит в том, чтобы предоставить список всех оценок всей возможной конфигурации для булевой функции, т.е.

Main> truth (\x y -> x && y)
[True,False,False,False]

Main> truth (\x y -> x || y)
[True,True,True,False]

В конце концов, должна быть напечатана таблица истинности (см. таблицу котла в конце этого сообщения, чтобы увидеть код, который производит это):

Main> main
T T T | T
T T F | T
T F T | T
T F F | F
F T T | T
F T F | F
F F T | T
F F F | T

Вот какой код котельной для тестирования и визуализации, какова цель этой функции:

class TruthTable a where
    truthTable :: Funk f => f -> a

instance TruthTable [String] where
    truthTable f = zipWith (++) (hCells (div (length t) 2)) (map showBool $ truth f)
        where
            showBool True = "| T"
            showBool False = "| F"
            hCells 1 = ["T ", "F "]
            hCells n = ["T " ++ x | x <- hCells (div n 2)] ++ ["F " ++ x | x <- hCells (div n 2)]

instance TruthTable [Char] where
    truthTable f = foldl1 join (truthTable f)
        where join a b = a ++ "\n" ++ b

instance TruthTable (IO a) where
    truthTable f = putStrLn (truthTable f) >> return undefined

main :: IO ()
main = truthTable (\x y z -> x `xor` y ==> z)

xor :: Bool -> Bool -> Bool
xor a b = not $ a == b

(==>) :: Bool -> Bool -> Bool
a ==> b = not $ a && not b

ОТВЕТЫ

Ответ 1

Нет проблем:

class    Funk a                  where  truth :: a  -> [Bool]
instance (IsBool a) => Funk [a]  where  truth =  map toBool
instance Funk Bool               where  truth =  \x -> [x]

instance (IsBool a, Funk b) => Funk (a -> b) where
    truth f = concat [truth (f $ fromBool True), truth (f $ fromBool False)]

class IsBool a where
    toBool :: a -> Bool
    fromBool :: Bool -> a

instance IsBool Bool where
    toBool = id
    fromBool = id

Вы даже можете сделать "почетные булевы", если хотите, например Integer с 0 и 1 и т.д.

Ответ 2

Способ Haskell98 - использовать newtypes для ([] Bool) и ((- > ) Bool b):

newtype LB = LB [Bool]
newtype FAB b = FAB (Bool -> b)

class    Funk a       where  truth :: a  -> [Bool]
instance Funk LB      where  truth =  \(LB x) -> x
instance Funk Bool    where  truth =  \x -> [x]

instance Funk b => Funk (FAB b) where
    truth (FAB f) = concat [truth (f True), truth (f False)]

Затем эта часть компилируется без каких-либо расширений LANGUAGE. Но это устраняет случай использования "истины", с которым легко работать.