Как получить даты создания/последнего изменения файла в Delphi?

Ответ 1

Дельфы предпочитают подход FindFirst (структура SearchRec имеет некоторые из них), но я бы предложил функцию API Win32 GetFileAttributesEx.

Ответ 2

Попробуйте

function FileAge(const FileName: string; out FileDateTime: TDateTime): Boolean;

Из SysUtils.

Ответ 3

Из бесплатной библиотеки DSiWin32:

function DSiFileTimeToDateTime(fileTime: TFileTime; var dateTime: TDateTime): boolean;
var
  sysTime: TSystemTime;
begin
  Result := FileTimeToSystemTime(fileTime, sysTime);
  if Result then
    dateTime := SystemTimeToDateTime(sysTime);
end; { DSiFileTimeToDateTime }

function  DSiGetFileTimes(const fileName: string; var creationTime, lastAccessTime,
  lastModificationTime: TDateTime): boolean; 
var
  fileHandle            : cardinal;
  fsCreationTime        : TFileTime;
  fsLastAccessTime      : TFileTime;
  fsLastModificationTime: TFileTime;
begin
  Result := false;
  fileHandle := CreateFile(PChar(fileName), GENERIC_READ, FILE_SHARE_READ, nil,
    OPEN_EXISTING, 0, 0);
  if fileHandle <> INVALID_HANDLE_VALUE then try
    Result :=
      GetFileTime(fileHandle, @fsCreationTime, @fsLastAccessTime,
         @fsLastModificationTime) and
      DSiFileTimeToDateTime(fsCreationTime, creationTime) and
      DSiFileTimeToDateTime(fsLastAccessTime, lastAccessTime) and
      DSiFileTimeToDateTime(fsLastModificationTime, lastModificationTime);
  finally
    CloseHandle(fileHandle);
  end;
end; { DSiGetFileTimes }

Ответ 4

Это должно работать, и это родной код Delphi.

function GetFileModDate(filename : string) : integer;
var
  F : TSearchRec;
begin
  FindFirst(filename,faAnyFile,F);
  Result := F.Time;
  //if you wanted a TDateTime, change the return type and use this line:
  //Result := FileDateToDatetime(F.Time);
  FindClose(F);
end;

Ответ 5

function GetFileModDate(filename : string) : TDateTime;
var
   F : TSearchRec;
begin
   FindFirst(filename,faAnyFile,F);
   Result := F.TimeStamp;
   //if you really wanted an Int, change the return type and use this line:
   //Result := F.Time;
   FindClose(F);
end;

F. Время с тех пор устарело, файл справки говорит, что используйте F.TimeStamp.
Просто обновить это из-за более поздних версий Delphi

Ответ 6

Вы можете вызвать функцию GetFileInformationByHandle winapi. Aparently JCL имеет функцию GetFileLastWrite, которую вы также можете использовать

Ответ 7

System.IOUtils имеют запись TFile с несколькими функциями для получения возраста файла, например. GetCreationTime, GetLastAccessTime, GetLastWriteTime