Примеры Tcl/Tk?

Tcl/Tk - это простой способ для небольших графических интерфейсов script.

Может ли кто-нибудь дать хороший пример с помощью кнопки и текстового виджета. Когда кнопка нажата, должна выполняться команда оболочки, а выход - в текстовый виджет.

Если у вас есть другие интересные и чистые примеры для полезных задач, добавьте их тоже.

ОТВЕТЫ

Ответ 1

Здесь приведен более полный пример использования файлов. Это автоматически будет прокручиваться. Для удобства использования вы, вероятно, хотите только автопрокрутить, если нижняя часть текста видна (например: если пользователь не переместил полосу прокрутки), но я оставлю это как упражнение для чтения, чтобы сохранить этот уже длинный пример от получения больше.

package require Tk

proc main {} {
    if {[lsearch -exact [font names] TkDefaultFont] == -1} {
        # older versions of Tk don't define this font, so pick something
        # suitable
        font create TkDefaultFont -family Helvetica -size 12
    }
    # in 8.5 we can use {*} but this will work in earlier versions
    eval font create TkBoldFont [font actual TkDefaultFont] -weight bold

    buildUI
}

proc buildUI {} {
    frame .toolbar
    scrollbar .vsb -command [list .t yview]
    text .t \
        -width 80 -height 20 \
        -yscrollcommand [list .vsb set] \
        -highlightthickness 0
    .t tag configure command -font TkBoldFont
    .t tag configure error   -font TkDefaultFont -foreground firebrick
    .t tag configure output  -font TkDefaultFont -foreground black

    grid .toolbar -sticky nsew
    grid .t .vsb  -sticky nsew
    grid rowconfigure . 1 -weight 1
    grid columnconfigure . 0 -weight 1

    set i 0
    foreach {label command} {
        date     {date} 
        uptime   {uptime} 
        ls       {ls -l}
    } {
        button .b$i -text $label -command [list runCommand $command]
        pack .b$i -in .toolbar -side left
        incr i
    }
}

proc output {type text} {
    .t configure -state normal
    .t insert end $text $type "\n"
    .t see end
    .t configure -state disabled
}

proc runCommand {cmd} {
    output command $cmd
    set f [open "| $cmd" r]
    fconfigure $f -blocking false
    fileevent $f readable  [list handleFileEvent $f]
}

proc closePipe {f} {
    # turn blocking on so we can catch any errors
    fconfigure $f -blocking true
    if {[catch {close $f} err]} {
        output error $err
    }
}

proc handleFileEvent {f} {
    set status [catch { gets $f line } result]
    if { $status != 0 } {
        # unexpected error
        output error $result
        closePipe $f

    } elseif { $result >= 0 } {
        # we got some output
        output normal $line

    } elseif { [eof $f] } {
        # End of file
        closePipe $f

    } elseif { [fblocked $f] } {
        # Read blocked, so do nothing
    }
}


main

Ответ 2

Некоторые предложения:

Чтобы добавить вывод в виджет текст, вместо указания строки 999999, вы можете использовать индекс end, который относится к позиции сразу после последней новой строки. Например,

.main insert end "$x\n"

Чтобы текст прокручивался при выводе команды, используйте команду see. Например, после добавления в текстовый виджет .main

.main see end

Вы также можете рассмотреть возможность ассемблирования вывода команды с помощью команды fileevent.

Ответ 3

Я могу начать... пожалуйста, предложите улучшения. Я хочу, чтобы он прокручивался, когда команда выводит

#!/usr/bin/wish

proc push_button {} {
    put_text
    .main see end
}

proc put_text {} {
  set f [ open "| date" r]
  while {[gets $f x] >= 0} {
    .main insert end "$x\n"    
  }
  catch {close $f}
}

button .but -text "Push Me" -command "push_button"
text .main -relief sunken -bd 2 -yscrollcommand ".scroll set"
scrollbar .scroll -command ".main yview"

pack .but
pack .main -side left -fill y
pack .scroll -side right -fill y