Xsl: для каждого счетчика циклов

Как сохранить итерации, которые произошли в xsl: for-each? (переменные в XSL неизменяемы)

Моя цель - найти максимальное количество детей для любого node на определенном уровне.

Например, я могу напечатать, что в этом опросе не более 2 узлов ответа для любого Вопроса:

<?xml version="1.0" encoding="ISO-8859-1"?>
<?xml-stylesheet type="text/xsl" href="testing.xsl"?>
<Survey>
  <Question>
    <Response text="Website" />
    <Response text="Print Ad" />
  </Question>
  <Question>
    <Response text="Yes" />
  </Question>
</Survey>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:template match="/">
  <html>
  <head>
  </head>
  <body>
    <xsl:for-each select="Survey">
      The survey has <xsl:value-of select="count(child::Question)"/> questions.  
      <br />
      <xsl:variable name="counter">0</xsl:variable>
      <xsl:for-each select="Question">
        <!-- TODO: increment the counter ??????? -->
      </xsl:for-each>
      No more than <xsl:value-of select="$counter"/> responses were returned for any question.
    </xsl:for-each>
  </body>
  </html>
</xsl:template>
</xsl:stylesheet>

ОТВЕТЫ

Ответ 1

Один не сохраняет итерации, которые произошли в xsl: for-each, потому что XSLT - это функциональный язык и переменные неизменяемы.

Следующее преобразование находит желаемый максимум:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

    <xsl:template match="/">
      <xsl:call-template name="maximum">
        <xsl:with-param name="pNodes" select="*/Question"/>
      </xsl:call-template>
    </xsl:template>

    <xsl:template name="maximum">
      <xsl:param name="pNodes"/>

      <xsl:variable name="vNumNodes" select="count($pNodes)"/>

      <xsl:choose>
        <xsl:when test="$vNumNodes = 1">
          <xsl:value-of select="count($pNodes[1]/Response)"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:variable name="vHalf" 
               select="floor($vNumNodes div 2)"/>

          <xsl:variable name="vMax1">
           <xsl:call-template name="maximum">
            <xsl:with-param name="pNodes"
                 select="$pNodes[not(position() > $vHalf)]"/>
           </xsl:call-template>
          </xsl:variable>

          <xsl:variable name="vMax2">
           <xsl:call-template name="maximum">
            <xsl:with-param name="pNodes"
                 select="$pNodes[position() > $vHalf]"/>
           </xsl:call-template>
          </xsl:variable>

          <xsl:value-of select=
           "$vMax1*($vMax1 >= $vMax2) + $vMax2*($vMax2 > $vMax1)"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

При применении к предоставленному XML-документу:

<Survey>
    <Question>
        <Response text="Website" />
        <Response text="Print Ad" />
    </Question>
    <Question>
        <Response text="Yes" />
    </Question>
</Survey>

получается желаемый результат:

2

Обратите внимание на следующее: шаблон с именем "maximum" вызывает себя рекурсивно и реализует DVC ( Divide and Conquer), чтобы минимизировать глубину стека рекурсии. Список узлов разбивается на два, максимальные значения двух списков вычисляются (рекурсивно) и возвращается больше из них.