Как вы напишете этот фрагмент Clojure в Ruby и/или Haskell?

Ответ 1

Я бы, вероятно, написал что-то подобное в Haskell, используя пакет Data.List.Split из Hackage:

import Data.List       (intercalate, transpose)
import Data.List.Split (splitEvery)

data Direction = Horizontal | Vertical deriving (Eq, Read, Show)

table :: Direction -> Int -> [a] -> [[a]]
table Horizontal cols xs = splitEvery cols xs
table Vertical   cols xs = let (q,r) = length xs `divMod` cols
                               q'    = if r == 0 then q else q+1
                           in transpose $ table Horizontal q' xs

showTable :: Show a => [[a]] -> String
showTable = intercalate "\n" . map (intercalate "\t" . map show)

main :: IO ()
main = mapM_ putStrLn [ showTable $ table Horizontal 3 [0..9]
                      , "---"
                      , showTable $ table Vertical   3 [0..9] ]

Некоторые из них, такие как тип Direction и трюк transpose, были получены из ответа jkramer. Я бы не использовал аргументы ключевого слова для чего-то вроде этого в Haskell (у него на самом деле нет таких вещей, но вы можете имитировать их с использованием записей, как в ответе Эдварда Кмета), но я сначала поставил эти аргументы, потому что это более полезно с частичным приложением (defaultTable = table Horizontal 1). Функция splitEvery просто группирует список в списки соответствующего размера; остальная часть кода должна быть простой. Функция table возвращает список списков; для получения строки функция showTable вставляет вкладки и новые строки. (Функция intercalate объединяет список списков, разделяя их с данным списком, аналогично Perl/Python/Ruby join, только для списков, а не только для строк.)

Ответ 2

Я не могу прочитать код clojure (я никогда не использовал язык), но на основе примеров, вот как я сделал бы это в Ruby.

def table array, cols, direction
   if direction==:down
      if array.size%cols != 0
         array[(array.size/cols+1)*cols-1]=nil
         #putting nil in the last space in the array
         #also fills all of the spaces before it
      end
      newarray=array.each_slice(array.size/cols).to_a
      table newarray.transpose.flatten(1), cols, :across
   elsif direction==:across
      array.each_slice(cols) do |row|
         puts row.join("  ")
      end
   else
      raise ArgumentError
   end
end

Ответ 3

Вот что я быстро взломал в Haskell. Я уверен, что это багги и может быть оптимизировано, но с чего начать:

import System.IO
import Data.List

data Direction = Horizontal | Vertical

main = do
    putStrLn $ table [1..9] 3 Horizontal
    putStrLn "---"
    putStrLn $ table [1..9] 3 Vertical


table xs ncol direction =
    case direction of
        Horizontal -> format (rows strings ncol)
        Vertical -> format (columns strings ncol)
    where
        format = intercalate "\n" . map (intercalate " ")

        strings = map show xs

        rows xs ncol =
            if length xs > ncol
                then take ncol xs : rows (drop ncol xs) ncol
                else [xs]

        columns xs = transpose . rows xs

Вывод:

1 2 3
4 5 6
7 8 9
---
1 4 7
2 5 8
3 6 9

Ответ 4

Мое рубиновое решение

def table(values)
  elements = values[:elements]
  cols = values[:cols]
  rows = (elements.count / cols.to_f).ceil

  erg = []

  rows.times do |i|
    cols.times do |j|
      erg << elements[values[:direction] == 'down' ? i+(rows*j) : j+i*(rows-1)]
      if erg.length == cols
        yield erg
        erg = []
      end        
    end
  end
  yield erg
end

Использование и вывод:

table(:elements => [0,1,2,3,4,5,6,7,8,9], :cols => 3) do |h,i,j|
  puts h.to_s << " " << i.to_s << " " << j.to_s
end

puts "---"

table(:elements => [0,1,2,3,4,5,6,7,8,9], :cols => 3, :direction => "down") do |h,i,j|
  puts h.to_s << " " << i.to_s << " " << j.to_s
end

0 1 2
3 4 5
6 7 8
9  
---
0 4 8
1 5 9
2 6 
3 7 

Ответ 5

Нарезка и застежка-молния дает прямое решение Ruby:

 def table(range, cols, direction=:right)
   if direction == :right
     range.each_slice cols
   else
     columns = range.each_slice((range.to_a.length - 1) / cols + 1).to_a
     columns[0].zip *columns[1..-1]
   end
 end


 puts table(0..9, 3, :down).map { |line| line.join ' ' }

Ответ 6

import Data.Array

stride :: Int -> Int -> Int
stride count cols = ceiling (fromIntegral count / fromIntegral cols)

type Direction = Int -> Int -> Int -> Int -> Int

right :: Direction
right count cols x y = y * cols + x

down :: Direction
down count cols x y = x * stride count cols + y

data Options = Options { cols :: Int, direction :: Direction }

options :: Options
options = Options 1 right

table :: Options -> [a] -> Array (Int,Int) (Maybe a)
table (Options cols dir) xs
    = listArray newRange (map f (range newRange))
    where count = length xs
          rows = stride count cols
          newRange = ((0,0),(rows-1,cols-1))
          f (y, x) 
              | ix < count = Just (xs !! ix)
              | otherwise = Nothing
              where ix = dir count cols x y

Это дает нам довольно идиоматическую аппроксимацию вашего исходного запроса в комплекте с необязательными аргументами:

*Main> table options { cols = 3 } [1..10]
listArray ((0,0),(3,2)) [Just 1, Just 2, Just 3
                        ,Just 4, Just 5, Just 6
                        ,Just 7, Just 8, Just 9
                        ,Just 10,Nothing,Nothing]

*Main> table options { direction = down, cols = 3 } [1..10]
listArray ((0,0),(3,2)) [Just 1,Just 5,Just 9
                        ,Just 2,Just 6,Just 10
                        ,Just 3,Just 7,Nothing
                        ,Just 4,Just 8,Nothing]

Я оставил промежуточные результаты в форме массива, так как вы указали, что вы планируете их форматировать как таблицу или теги ul.