XSLT: как получить список всех используемых пространств имен

Я пишу таблицу стилей XSLT 1.0 для преобразования XML-документов с несколькими именами в HTML. В каком-то месте в результате HTML я хочу перечислить все пространства имен, которые произошли в документе.

Возможно ли это?

Я подумал о чем-то вроде

<xsl:for-each select="//*|//@*">
  <xsl:value-of select="namespace-uri(.)" />
</xsl:for-each>

но, конечно, я получаю gazillions дубликатов. Поэтому мне пришлось бы каким-то образом отфильтровать, что я уже напечатал.

Рекурсивные вызовы шаблонов будут работать, но я не могу обернуть голову тем, как достичь всех элементов.

Доступ к //@xmlns:* напрямую невозможен, потому что нельзя получить доступ к этому через XPath (одному не разрешено связывать любой префикс с пространством имен xmlns:).

ОТВЕТЫ

Ответ 1

Другое без функций расширения:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="*">
        <xsl:param name="pNamespaces" select="'&#xA;'"/>
        <xsl:variable name="vNamespaces">
            <xsl:variable name="vMyNamespaces">
                <xsl:value-of select="$pNamespaces"/>
                <xsl:for-each select="namespace::*
                                        [not(contains(
                                                 $pNamespaces,
                                                 concat('&#xA;',.,'&#xA;')))]">
                    <xsl:value-of select="concat(.,'&#xA;')"/>
                </xsl:for-each>
            </xsl:variable>
            <xsl:variable name="vChildsNamespaces">
                <xsl:apply-templates select="*[1]">
                    <xsl:with-param name="pNamespaces"
                                        select="$vMyNamespaces"/>
                </xsl:apply-templates>
            </xsl:variable>
            <xsl:value-of select="concat(substring($vMyNamespaces,
                                                   1 div not(*)),
                                         substring($vChildsNamespaces,
                                                   1 div boolean(*)))"/>
        </xsl:variable>
        <xsl:variable name="vFollowNamespaces">
            <xsl:apply-templates select="following-sibling::*[1]">
                <xsl:with-param name="pNamespaces" select="$vNamespaces"/>
            </xsl:apply-templates>
        </xsl:variable>
        <xsl:value-of
             select="concat(substring($vNamespaces,
                                      1 div not(following-sibling::*)),
                            substring($vFollowNamespaces,
                                      1 div boolean(following-sibling::*)))"/>
    </xsl:template>
</xsl:stylesheet>

Выход (с образцом ввода Dimitre):

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

EDIT. Также это выражение XPath:

//*/namespace::*[not(. = ../../namespace::*|preceding::*/namespace::*)]

В качестве доказательства эта таблица стилей:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">
        <xsl:for-each select="//*/namespace::*
                                     [not(. = ../../namespace::*|
                                              preceding::*/namespace::*)]">
            <xsl:value-of select="concat(.,'&#xA;')"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Вывод:

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

РЕДАКТИРОВАТЬ 4: Тот же эффективный, что и преобразование с двумя проходами.

Эта таблица стилей:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:key name="kElemByNSURI"
             match="*[namespace::*[not(. = ../../namespace::*)]]"
              use="namespace::*[not(. = ../../namespace::*)]"/>
    <xsl:template match="/">
        <xsl:for-each select=
            "//namespace::*[not(. = ../../namespace::*)]
                           [count(..|key('kElemByNSURI',.)[1])=1]">
            <xsl:value-of select="concat(.,'&#xA;')"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Вывод:

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

РЕДАКТИРОВАТЬ 5: когда вы имеете дело с процессором XSLT без реализации namespace ax (например, TransforMiix), вы можете извлекать пространства имен, фактически используемые с этой таблицей стилей:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:key name="kElemByNSURI" match="*|@*" use="namespace-uri()"/>
    <xsl:template match="/">
        <xsl:for-each select=
            "(//*|//@*)[namespace-uri()!='']
                       [count(.|key('kElemByNSURI',namespace-uri())[1])=1]">
            <xsl:value-of select="concat(namespace-uri(),'&#xA;')"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Выход TransforMiix:

mynamespace2

Ответ 2

Это преобразование:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:template match="/">
   <xsl:for-each select=
    "//namespace::*[not(. = ../../namespace::*)]">
     <xsl:value-of select="concat(.,'&#xA;')"/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

при применении к этому XML-документу:

<authors xmlns:user="mynamespace">
  <?ttt This is a PI ?>
  <author xmlns:user2="mynamespace2">
    <name idd="VH">Victor Hugo</name>
    <user2:name idd="VH">Victor Hugo</user2:name>
    <nationality xmlns:user3="mynamespace3">French</nationality>
  </author>
</authors>

создает желаемый, правильный результат:

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

Обновление

Как заметил @svick, вышеупомянутое решение будет по-прежнему создавать дубликаты пространств имен, например, со следующим XML-документом:

<authors xmlns:user="mynamespace">
  <?ttt This is a PI ?>
  <author xmlns:user2="mynamespace2">
    <name idd="VH">Victor Hugo</name>
    <user2:name idd="VH">Victor Hugo</user2:name>
    <nationality xmlns:user3="mynamespace3">French</nationality>
  </author>
  <t xmlns:user2="mynamespace2"/>
</authors>

пространство имен "mynamespace2" будет выведено дважды на выходе.

Следующее преобразование устраняет эту проблему:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 exclude-result-prefixes="ext">
 <xsl:output method="text"/>

 <xsl:key name="kNSbyURI" match="n" use="."/>

 <xsl:template match="/">
   <xsl:variable name="vrtfNS">
       <xsl:for-each select=
        "//namespace::*[not(. = ../../namespace::*)]">
         <n><xsl:value-of select="."/></n>
       </xsl:for-each>
   </xsl:variable>

   <xsl:variable name="vNS" select="ext:node-set($vrtfNS)/*"/>

   <xsl:for-each select=
    "$vNS[generate-id()
         =
          generate-id(key('kNSbyURI',.)[1])
         ]">
     <xsl:value-of select="concat(., '&#xA;')"/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется к вышеуказанному XML-документу, оно производит только все уникальные пространства имен в документе:

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

Часть II: решение XSLT 2.0.

Решение XSLT 2.0 представляет собой простой однострочный интерфейс XPath 2.0:

distinct-values(//namespace::*)