Clojure макрос для вызова наборов Java на основе карты?

Я пишу обертку Clojure для библиотеки Java Braintree, чтобы предоставить более сжатый и идиоматический интерфейс. Я хотел бы предоставить функции для создания объектов Java быстро и кратко, например:

(transaction-request :amount 10.00 :order-id "user42")

Я знаю, что могу сделать это явно, как показано в этом вопросе:

(defn transaction-request [& {:keys [amount order-id]}]
  (doto (TransactionRequest.)
    (.amount amount)
    (.orderId order-id)))

Но это повторяется для многих классов и становится более сложным, если параметры являются необязательными. Используя отражение, можно более четко определить эти функции:

(defn set-obj-from-map [obj m]
  (doseq [[k v] m]
    (clojure.lang.Reflector/invokeInstanceMethod
      obj (name k) (into-array Object [v])))
  obj)

(defn transaction-request [& {:as m}]
  (set-obj-from-map (TransactionRequest.) m))

(defn transaction-options-request [tr & {:as m}]
  (set-obj-from-map (TransactionOptionsRequest. tr) m))

Очевидно, я хотел бы избежать отражения, если это вообще возможно. Я попытался определить макрокоманду set-obj-from-map, но мой макро-fu недостаточно силен. Вероятно, для этого требуется eval, как описано здесь.

Есть ли способ вызвать метод Java, указанный во время выполнения, без использования отражения?

Спасибо заранее!

Обновленное решение:

Следуя рекомендациям Joost, я смог решить проблему, используя подобную технику. Макрос использует отражение во время компиляции для определения тех методов setter, которые класс имеет, а затем выплескивает формы для проверки параметра на карте и вызова метода с его значением.

Здесь макрос и пример используют:

; Find only setter methods that we care about
(defn find-methods [class-sym]
  (let [cls (eval class-sym)
        methods (.getMethods cls)
        to-sym #(symbol (.getName %))
        setter? #(and (= cls (.getReturnType %))
                      (= 1 (count (.getParameterTypes %))))]
    (map to-sym (filter setter? methods))))

; Convert a Java camelCase method name into a Clojure :key-word
(defn meth-to-kw [method-sym]
  (-> (str method-sym)
      (str/replace #"([A-Z])"
                   #(str "-" (.toLowerCase (second %))))
      (keyword)))

; Returns a function taking an instance of klass and a map of params
(defmacro builder [klass]
  (let [obj (gensym "obj-")
        m (gensym "map-")
        methods (find-methods klass)]
    `(fn [~obj ~m]
       [email protected](map (fn [meth]
               `(if-let [v# (get ~m ~(meth-to-kw meth))] (. ~obj ~meth v#)))
              methods)
       ~obj)))

; Example usage
(defn transaction-request [& {:as params}]
  (-> (TransactionRequest.)
    ((builder TransactionRequest) params)
    ; some further use of the object
  ))