Подтверждение модуля в запись

Предположим, что у меня есть произвольный модуль

module Foo where
foo :: Moo -> Goo
bar :: Car -> Far
baz :: Can -> Haz

где foo, bar и baz правильно реализованы и т.д.

Я хотел бы подтвердить этот модуль на автоматически созданный тип данных и соответствующий объект:

import Foo (Moo, Goo, Car, Far, Can, Haz)
import qualified Foo

data FooModule = Foo
  { foo :: Moo -> Goo
  , bar :: Car -> Far
  , baz :: Can -> Haz
  }

_Foo_ = Foo
  { foo = Foo.foo
  , bar = Foo.bar
  , baz = Foo.baz
  }

Имена должны быть точно такими же, как исходный модуль.

Я мог бы сделать это вручную, но это очень утомительно, поэтому я хотел бы написать код для выполнения этой задачи для меня.

Я не уверен, как подойти к такой задаче. Предоставляет ли Template Haskell способ проверки модулей? Должен ли я подключаться к некоторым GHC api? Или мне так же хорошо, что и более ad-hoc-подход, например, очистка страниц пикши?

ОТВЕТЫ

Ответ 1

(Это для GHC-7.4.2, вероятно, он не будет компилироваться с HEAD или 7.6 из-за некоторых изменений в Outputable). Я не нашел ничего для проверки модулей в TH.

{-# LANGUAGE NoMonomorphismRestriction #-}
{-# OPTIONS -Wall #-}
import GHC
import GHC.Paths -- ghc-paths package
import Outputable
import GhcMonad

main :: IO ()
main = runGhc (Just libdir) $ goModule "Data.Map"

goModule :: GhcMonad m => String -> m ()
goModule modStr = do
  df <- getSessionDynFlags
  _ <- setSessionDynFlags df  
  -- ^ Don't know if this is the correct way, but it works for this purpose

  setContext [IIDecl (simpleImportDecl (mkModuleName modStr))]
  infos <- mapM getInfo =<< getNamesInScope 
  let ids = onlyIDs infos
  liftIO . putStrLn . showSDoc . render $ ids 

onlyIDs :: [Maybe (TyThing, Fixity, [Instance])] -> [Id]
onlyIDs infos = [ i | Just (AnId i, _, _) <- infos ] 

render :: [Id] -> SDoc
render ids = mkFields ids $$ text "------------" $$ mkInits ids 

mkFields :: [Id] -> SDoc
mkFields = vcat . map (\i ->
  text "," <+> pprUnqual i <+> text "::" <+> ppr (idType i))

mkInits :: [Id] -> SDoc
mkInits = vcat . map (\i ->
  text "," <+> pprUnqual i <+> text "=" <+> ppr i)


-- * Helpers

withUnqual :: SDoc -> SDoc
withUnqual  = withPprStyle (mkUserStyle neverQualify AllTheWay)

pprUnqual :: Outputable a => a -> SDoc
pprUnqual = withUnqual . ppr