Как я могу использовать emacs-jedi для работы с конкретными проектами virtualenvs

Я хотел бы, чтобы emacs-jedi обнаружил, когда я редактирую файлы в разных проектах, и использую соответствующий virtualenv, если он доступен. По соглашению мои virtualenvs имеют то же имя, что и мои проекты. Они расположены в $HOME/.virtualenvs/

Я нашел kenobi.el, но предполагает, что virtualenvs находятся в каталоге bin в корне проекта. У него также есть несколько других функций, которые мне вообще не нужны.

С вдохновением от kenobi.el, я написал следующую инициализацию для джедаев. Он работает очень хорошо, но не идеально.

Если я импортирую библиотеку A из моего проекта и A импортирует B. Я могу перейти к определениям, определенным A, но после этого я не могу продолжать прыгать в определения из B.

Моя инициализация:

(defun project-directory (buffer-name)
  (let ((git-dir (file-name-directory buffer-name)))
    (while (and (not (file-exists-p (concat git-dir ".git")))
                git-dir)
      (setq git-dir
            (if (equal git-dir "/")
                nil
              (file-name-directory (directory-file-name git-dir)))))
    git-dir))

(defun project-name (buffer-name)
  (let ((git-dir (project-directory buffer-name)))
    (if git-dir
        (file-name-nondirectory
         (directory-file-name git-dir))
      nil)))

(defun virtualenv-directory (buffer-name)
  (let ((venv-dir (expand-file-name
                   (concat "~/.virtualenvs/" (project-name buffer-name)))))
    (if (and venv-dir (file-exists-p venv-dir))
        venv-dir
      nil)))    

(defun jedi-setup-args ()
  (let ((venv-dir (virtualenv-directory buffer-file-name)))
    (when venv-dir
      (set (make-local-variable 'jedi:server-args) (list "--virtual-env" venv-dir)))))

(setq jedi:setup-keys t)
(setq jedi:complete-on-dot t)
(add-hook 'python-mode-hook 'jedi-setup-args)
(add-hook 'python-mode-hook 'jedi:setup)

Что не так, как я инициализирую джедай?

ОТВЕТЫ

Ответ 1

Теперь я решил использовать решение, которое использует пакет virtualenvwrapper ELPA для активации virtualenvs, позволяя emacs-jedi забирать virtualenv из переменной окружения VIRTUAL_ENV.

Вот полная, работающая, emacs-jedi инициализация:

(defun project-directory (buffer-name)
  "Return the root directory of the project that contain the
given BUFFER-NAME. Any directory with a .git or .jedi file/directory
is considered to be a project root."
  (interactive)
  (let ((root-dir (file-name-directory buffer-name)))
    (while (and root-dir
                (not (file-exists-p (concat root-dir ".git")))
                (not (file-exists-p (concat root-dir ".jedi"))))
      (setq root-dir
            (if (equal root-dir "/")
                nil
              (file-name-directory (directory-file-name root-dir)))))
    root-dir))

(defun project-name (buffer-name)
  "Return the name of the project that contain the given BUFFER-NAME."
  (let ((root-dir (project-directory buffer-name)))
    (if root-dir
        (file-name-nondirectory
         (directory-file-name root-dir))
      nil)))

(defun jedi-setup-venv ()
  "Activates the virtualenv of the current buffer."
  (let ((project-name (project-name buffer-file-name)))
    (when project-name (venv-workon project-name))))

(setq jedi:setup-keys t)
(setq jedi:complete-on-dot t)
(add-hook 'python-mode-hook 'jedi-setup-venv)
(add-hook 'python-mode-hook 'jedi:setup)

Помните, что сначала нужно установить virtualenvwrapper.

Прочитайте документацию virtualenvwrapper для альтернативного способа автоматической активации виртуальной среды проекта. Короче говоря, вы можете создать файл .dir-locals.el в корне вашего проекта со следующим содержимым:

((python-mode . ((project-venv-name . "myproject-env"))))

Измените "myproject-env" на имя своего виртуального пользователя и активируйте виртуальную окружение с помощью python-mode hook:

(add-hook 'python-mode-hook (lambda ()
                              (hack-local-variables)
                              (venv-workon project-venv-name)))
(add-hook 'python-mode-hook 'jedi:setup)