Как связать нажатие клавиши на клавиатуре

Я получаю зависание Элма, но я продолжаю бороться с сигналами и нажатиями на клавиатуре. Приведенный ниже код является примером пакета start-app. Я хотел бы иметь это, когда я нажимаю пробел, чтобы счетчик увеличивался. Как это делается в приведенном ниже примере?

import Html exposing (div, button, text)
import Html.Events exposing (onClick)
import StartApp.Simple as StartApp


main =
  StartApp.start { model = model, view = view, update = update }


model = 0


view address model =
  div []
    [ button [ onClick address Decrement ] [ text "-" ]
    , div [] [ text (toString model) ]
    , button [ onClick address Increment ] [ text "+" ]
    ]


type Action = Increment | Decrement


update action model =
  case action of
    Increment -> model + 1
    Decrement -> model - 1

ОТВЕТЫ

Ответ 1

Вам нужно будет использовать обычный StartApp, а не StartApp.Simple, потому что он предоставляет средства для использования эффектов и задач.

Для Action нужен конструктор NoOp, чтобы наше представление оставалось неизменным, когда нажатие клавиши не является пробелом.

Тогда вам понадобится функция, которая сопоставляет значение Keyboard.presses с Action. Здесь обновленный код:

import Html exposing (div, button, text)
import Html.Events exposing (onClick)
import StartApp
import Effects exposing (Never)
import Task 
import Keyboard
import Char

app =
  StartApp.start
    { init = init
    , view = view
    , update = update
    , inputs = [ Signal.map spaceToInc Keyboard.presses ]
    }

main =
  app.html

type alias Model = Int

init =
  (0, Effects.none)

view address model =
  div []
    [ button [ onClick address Decrement ] [ text "-" ]
    , div [] [ text (toString model) ]
    , button [ onClick address Increment ] [ text "+" ]
    ]

type Action
  = Increment
  | Decrement
  | NoOp

update action model =
  case action of
    NoOp -> (model, Effects.none)
    Increment -> (model + 1, Effects.none)
    Decrement -> (model - 1, Effects.none)

spaceToInc : Int -> Action
spaceToInc keyCode =
  case (Char.fromCode keyCode) of
    ' ' -> Increment
    _ -> NoOp

port tasks : Signal (Task.Task Never ())
port tasks =
  app.tasks