Почему вызов GetDIBits завершился неудачей на Win64?

У меня есть вызов GetDIBits, который отлично работает в 32-разрядной версии, но не работает на 64-разрядной версии. Несмотря на разные значения для ручек, содержимое структуры bitmapinfo одинаково.

Вот самый маленький (по крайней мере, слегка структурированный) пример кода, который я мог бы придумать для воспроизведения ошибки. Я тестировал с Delphi 10 Seattle Update 1, но ошибка, похоже, происходит даже с другими версиями Delphi.

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  Winapi.Windows,
  System.SysUtils,
  Vcl.Graphics;

type
  TRGBALine = array[Word] of TRGBQuad;
  PRGBALine = ^TRGBALine;

type
  { same structure as TBitmapInfo, but adds space for two more entries in bmiColors }
  TMyBitmapInfo = record
    bmiHeader: TBitmapInfoHeader;
    bmiColors: array[0..2] of TRGBQuad;
  public
    constructor Create(AWidth, AHeight: Integer);
  end;

constructor TMyBitmapInfo.Create(AWidth, AHeight: Integer);
begin
  FillChar(bmiHeader, Sizeof(bmiHeader), 0);
  bmiHeader.biSize := SizeOf(bmiHeader);
  bmiHeader.biWidth := AWidth;
  bmiHeader.biHeight := -AHeight;  //Otherwise the image is upside down.
  bmiHeader.biPlanes := 1;
  bmiHeader.biBitCount := 32;
  bmiHeader.biCompression := BI_BITFIELDS;
  bmiHeader.biSizeImage := 4*AWidth*AHeight; // 4 = 32 Bits/Pixel div 8 Bits/Byte
  bmiColors[0].rgbRed := 255;
  bmiColors[1].rgbGreen := 255;
  bmiColors[2].rgbBlue := 255;
end;

procedure Main;
var
  bitmap: TBitmap;
  res: Cardinal;
  Bits: PRGBALine;
  buffer: TMyBitmapInfo;
  BitmapInfo: TBitmapInfo absolute buffer;
  BitsSize: Cardinal;
  icon: TIcon;
  IconInfo: TIconInfo;
begin
  bitmap := TBitmap.Create;
  try
    icon := TIcon.Create;
    try
      icon.LoadFromResourceID(0, Integer(IDI_WINLOGO));
      if not GetIconInfo(icon.Handle, IconInfo) then begin
        Writeln('Error GetIconInfo: ', GetLastError);
        Exit;
      end;
      bitmap.PixelFormat := pf32bit;
      bitmap.Handle := IconInfo.hbmColor;
      BitsSize := BytesPerScanline(bitmap.Width, 32, 32) * bitmap.Height;
      Bits := AllocMem(BitsSize);
      try
        ZeroMemory(Bits, BitsSize);
        buffer := TMyBitmapInfo.Create(bitmap.Width, bitmap.Height);
        res := GetDIBits(bitmap.Canvas.Handle, bitmap.Handle, 0, bitmap.Height, Bits, BitmapInfo, DIB_RGB_COLORS);
        if res = 0 then begin
          Writeln('Error GetDIBits: ', GetLastError);
          Exit;
        end;
        Writeln('Succeed');
      finally
        FreeMem(Bits);
      end;
    finally
      icon.Free;
    end;
  finally
    bitmap.Free;
  end;
end;

begin
  try
    Main;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

ОТВЕТЫ

Ответ 1

Обновление. Комментарий к этому ответу указывает способ отказа вашего кода. Порядок оценки bitmap.Handle и bitmap.Canvas.Handle имеет значение. Поскольку порядок оценки параметров undefined, ваша программа имеет поведение undefined. И это объясняет, почему программы x86 и x64 отличаются поведением.

Таким образом, вы можете решить проблему, назначив битмап-дескриптор и контекст устройства локальным переменным в соответствующем порядке, а затем передав их как аргументы GetDIBits. Но я все же считаю, что код намного лучше избегать класса VCL TBitmap и напрямую использовать вызовы GDI, как в приведенном ниже коде.

Я считаю, что ваша ошибка - передать обработчик bitmap и его обработчик холста. Вместо этого вы должны передать, например, контекст устройства, полученный вызовом CreateCompatibleDC(0). Или перейдите IconInfo.hbmColor в GetDIBits. Но не передавайте дескриптор TBitmap и дескриптор его холста.

Я также не вижу никакой цели для созданного TBitmap. Все, что вам нужно, это получить ширину и высоту IconInfo.hbmColor. Вам не нужно создавать TBitmap для этого.

Итак, если бы я был вами, я бы удалил TBitmap и использовал CreateCompatibleDC(0) для получения контекста устройства. Это должно значительно упростить код.

Вам также необходимо удалить растровые изображения, возвращенные вызовом, в GetIconInfo, но я думаю, вы уже знаете это и удалили этот код из вопроса для простоты.

Откровенно говоря, объекты VCL просто мешают здесь. На самом деле гораздо проще напрямую вызвать функции GDI. Возможно, что-то вроде этого:

procedure Main;
var
  res: Cardinal;
  Bits: PRGBALine;
  bitmap: Winapi.Windows.TBitmap;
  DC: HDC;
  buffer: TMyBitmapInfo;
  BitmapInfo: TBitmapInfo absolute buffer;
  BitsSize: Cardinal;
  IconInfo: TIconInfo;
begin
  if not GetIconInfo(LoadIcon(0, IDI_WINLOGO), IconInfo) then begin
    Writeln('Error GetIconInfo: ', GetLastError);
    Exit;
  end;
  try
    if GetObject(IconInfo.hbmColor, SizeOf(bitmap), @bitmap) = 0 then begin
      Writeln('Error GetObject');
      Exit;
    end;

    BitsSize := BytesPerScanline(bitmap.bmWidth, 32, 32) * abs(bitmap.bmHeight);
    Bits := AllocMem(BitsSize);
    try
      buffer := TMyBitmapInfo.Create(bitmap.bmWidth, abs(bitmap.bmHeight));
      DC := CreateCompatibleDC(0);
      res := GetDIBits(DC, IconInfo.hbmColor, 0, abs(bitmap.bmHeight), Bits, BitmapInfo,
        DIB_RGB_COLORS);
      DeleteDC(DC);
      if res = 0 then begin
        Writeln('Error GetDIBits: ', GetLastError);
        Exit;
      end;
      Writeln('Succeed');
    finally
      FreeMem(Bits);
    end;
  finally
    DeleteObject(IconInfo.hbmMask);
    DeleteObject(IconInfo.hbmColor);
  end;
end;