Gradle jacocoTestReport не работает?

Я попытался получить покрытие кода в проекте spring - gradle, используя gradle плагин jacoco.

Файл build.gradle содержит следующие

apply plugin: "jacoco"

    jacoco {
        toolVersion = "0.7.1.201405082137"
        reportsDir = file("$buildDir/customJacocoReportDir")
    }

    jacocoTestReport {
    reports {
        xml.enabled false
        csv.enabled false
        html.destination "${buildDir}/jacocoHtml"
    }
}

Затем я запустил

gradle test jacocoTestReport

Когда после создания файла build/reports создается файл test.exec.

Кроме этого ничего не происходит.

Как я могу получить отчет HTML?

ОТВЕТЫ

Ответ 1

Следующее помогло. его в образцах/тестировании /jacaco из gradle-2.3-all.zip с https://gradle.org/releases/

apply plugin: "java"

apply plugin: "jacoco"

jacoco {
    toolVersion = "0.7.1.201405082137"
    reportsDir = file("$buildDir/customJacocoReportDir")
}

repositories {
    mavenCentral()
}

dependencies {
    testCompile "junit:junit:4.+"
}

test {
    jacoco {
        append = false
        destinationFile = file("$buildDir/jacoco/jacocoTest.exec")
        classDumpFile = file("$buildDir/jacoco/classpathdumps")
    }
}


jacocoTestReport {
    reports {
        xml.enabled false
        csv.enabled false
        html.destination "${buildDir}/jacocoHtml"
    }
}

Ответ 2

Вам не нужно настраивать reportsDir/destinationFile

Поскольку jacoco имеет для них значения по умолчанию.

build.gradle:

plugins {
    id 'java'
    id 'jacoco'
}

jacocoTestReport {
    reports {
        xml.enabled true
        html.enabled true
        csv.enabled true
    }
}

repositories {
    jcenter()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.12'
}

Выполнить gradle test jacocoTestReport

Отчет о тестировании можно найти в каталоге ./build/reports/jacoco/test.

Выход HTML находится в каталоге ./build/reports/jacoco/test/html.