Отобразите все ветки потомков первого уровня, используя Git

Ответ 1

Вы можете сделать это следующим образом.

Сначала обычная преамбула:

#! /usr/bin/perl

use warnings;
use strict;

Используйте git for-each-ref, чтобы собрать SHA-1 и имя для каждого ref:

sub refs {
  open my $fh, "-|", "git", "for-each-ref",
                            "--format=%(objectname)\t%(refname:short)"
    or die "$0: failed to run git for-each-ref";

  my %ref2sha;
  while (<$fh>) {
    chomp;
    my($sha,$ref) = split /\t/;
    $ref2sha{$ref} = $sha;
  }

  \%ref2sha;
}

Если коммит является дочерним элементом HEAD, то набор коммитов, достижимый из HEAD, исключая все доступные из рассматриваемого коммита, является пустым. Мы можем проверить это соотношение с git rev-list.

sub is_child {
  my($ref) = @_;

  # git rev-list ^dev master
  my $refs = `git rev-list ^$ref HEAD -- 2>&1`;
  die "$0: git rev-list-failed.\n$refs" if $?;

  $refs !~ /\S/;
}

Для каждого ref, являющегося потомком HEAD, но не эквивалентного HEAD, мы рассмотрим путь от HEAD к этой ссылке, используя git log. Если путь содержит кончик другой ветки, ref не может быть дочерним слоем первого уровня.

Все оставшиеся в живых этой перчаткой - дети первого уровня.

chomp(my $head = `git rev-parse HEAD 2>&1`);
die "$0: git rev-parse failed.\n$head" if $?;

my $ref2sha = refs;
my %headsha = reverse %$ref2sha;

REF:
foreach my $ref (keys %$ref2sha) {
  my $refsha = $ref2sha->{$ref};

  next if $refsha eq $head || !is_child $ref;

  my @log = `git log --pretty=format:%H ..$ref 2>&1`;
  die "$0: git log failed.\[email protected]" if $?;
  for (@log) {
    chomp;
    next if $_ eq $refsha;
    next REF if exists $headsha{$_};
  }

  print $ref, "\n";
}