Inno Setup: как автоматически удалить предыдущую установленную версию?

Я использую Inno Setup для создания установщика.

Я хочу, чтобы установщик автоматически удалял предыдущую установленную версию, а не перезаписывал ее. Как я могу это сделать?

ОТВЕТЫ

Ответ 1

Вы должны иметь возможность прочитать строку удаления из реестра, учитывая AppId (т.е. значение, которое вы использовали для AppID в разделе [Setup]). Его можно найти в разделе Software\Microsoft\Windows\CurrentVersion\Uninstall\{AppId}\ (может быть либо HKLM, либо HKCU, поэтому лучше проверить оба), где {AppId} следует заменить фактическим значением, которое вы использовали. Найдите значения UninstallString или QuietUninstallString и используйте функцию Exec, чтобы запустить ее из вашей функции события InitializeSetup().

Обновление: удалено нерабочее альтернативное решение с помощью [Run] -раздела с {uninstallexe} - благодаря всем комментаторам, которые указали это!

Ответ 2

Я использовал следующее. Я не уверен, что это самый простой способ сделать это, но он работает.

В этом случае используется {#emit SetupSetting("AppId")}, который опирается на препроцессор Inno Setup. Если вы не используете это, вырезайте и вставьте свой идентификатор приложения напрямую.

/////////////////////////////////////////////////////////////////////
function GetUninstallString(): String;
var
  sUnInstPath: String;
  sUnInstallString: String;
begin
  sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
  sUnInstallString := '';
  if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
    RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
  Result := sUnInstallString;
end;


/////////////////////////////////////////////////////////////////////
function IsUpgrade(): Boolean;
begin
  Result := (GetUninstallString() <> '');
end;


/////////////////////////////////////////////////////////////////////
function UnInstallOldVersion(): Integer;
var
  sUnInstallString: String;
  iResultCode: Integer;
begin
// Return Values:
// 1 - uninstall string is empty
// 2 - error executing the UnInstallString
// 3 - successfully executed the UnInstallString

  // default return value
  Result := 0;

  // get the uninstall string of the old app
  sUnInstallString := GetUninstallString();
  if sUnInstallString <> '' then begin
    sUnInstallString := RemoveQuotes(sUnInstallString);
    if Exec(sUnInstallString, '/SILENT /NORESTART /SUPPRESSMSGBOXES','', SW_HIDE, ewWaitUntilTerminated, iResultCode) then
      Result := 3
    else
      Result := 2;
  end else
    Result := 1;
end;

/////////////////////////////////////////////////////////////////////
procedure CurStepChanged(CurStep: TSetupStep);
begin
  if (CurStep=ssInstall) then
  begin
    if (IsUpgrade()) then
    begin
      UnInstallOldVersion();
    end;
  end;
end;

Альтернативы

См. также это сообщение в блоге "Inno Setup Script Пример для сравнения версий" , который идет на один шаг дальше и читает номер версии любую ранее установленную версию и сравнивает номер версии с номером текущего установочного пакета.

Ответ 3

При использовании Inno Setup нет причин для удаления предыдущей версии, если эта версия не была установлена ​​другой программой-установщиком. В противном случае обновление выполняется автоматически.

Ответ 4

Если вы просто хотите удалить старые значки (потому что вы изменили/обновили), вы можете использовать это:

; attempt to remove previous versions' icons
[InstallDelete]
Type: filesandordirs; Name: {group}\*;

Это запускается "в начале установки", поэтому в основном удаляет старые значки, и ваши новые будут по-прежнему установлены там после завершения.

Я просто делаю это при каждой установке "на случай, если что-то изменилось" значок мудрый (все равно все переустанавливается).

Ответ 5

Ответ, предоставленный Крейгом МакКуином, вполне жизнеспособен. Хотя, я бы добавил эти комментарии:

  • Код {#emit SetupSetting("AppId")} не работает для меня, поэтому я просто добавляю свой идентификатор приложения.
  • Я не хотел запускать мою программу удаления, потому что у меня есть файл конфигурации INI, хранящийся в папке AppData/, который удаляется деинсталлятором, и я не хочу, чтобы его удаляли при установке новой версии. Итак, я немного изменил код, предоставленный Крейгом МакКуином, чтобы удалить каталог, в котором установлена ​​программа, после получения его пути.

Итак, в отношении кода Крейга МакКуина изменения:

  • Извлеките ключ InstallLocation вместо клавиши UninstallString.
  • Используйте функцию DelTree вместо Exec(sUnInstallString, ...)

Ответ 6

Я получил отредактированный код @Crain Mc-Queen, я думаю, что этот код лучше, потому что не нужно изменять в другом проекте:

[Code]
function GetNumber(var temp: String): Integer;
var
  part: String;
  pos1: Integer;
begin
  if Length(temp) = 0 then
  begin
    Result := -1;
    Exit;
  end;
    pos1 := Pos('.', temp);
    if (pos1 = 0) then
    begin
      Result := StrToInt(temp);
    temp := '';
    end
    else
    begin
    part := Copy(temp, 1, pos1 - 1);
      temp := Copy(temp, pos1 + 1, Length(temp));
      Result := StrToInt(part);
    end;
end;

function CompareInner(var temp1, temp2: String): Integer;
var
  num1, num2: Integer;
begin
    num1 := GetNumber(temp1);
  num2 := GetNumber(temp2);
  if (num1 = -1) or (num2 = -1) then
  begin
    Result := 0;
    Exit;
  end;
      if (num1 > num2) then
      begin
        Result := 1;
      end
      else if (num1 < num2) then
      begin
        Result := -1;
      end
      else
      begin
        Result := CompareInner(temp1, temp2);
      end;
end;

function CompareVersion(str1, str2: String): Integer;
var
  temp1, temp2: String;
begin
    temp1 := str1;
    temp2 := str2;
    Result := CompareInner(temp1, temp2);
end;

function InitializeSetup(): Boolean;
var
  oldVersion: String;
  uninstaller: String;
  ErrorCode: Integer;
  vCurID      :String;
  vCurAppName :String;
begin
  vCurID:= '{#SetupSetting("AppId")}';
  vCurAppName:= '{#SetupSetting("AppName")}';
  //remove first "{" of ID
  vCurID:= Copy(vCurID, 2, Length(vCurID) - 1);
  //
  if RegKeyExists(HKEY_LOCAL_MACHINE,
    'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1') then
  begin
    RegQueryStringValue(HKEY_LOCAL_MACHINE,
      'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
      'DisplayVersion', oldVersion);
    if (CompareVersion(oldVersion, '{#SetupSetting("AppVersion")}') < 0) then      
    begin
      if MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. Continue to use this old version?',
        mbConfirmation, MB_YESNO) = IDYES then
      begin
        Result := False;
      end
      else
      begin
          RegQueryStringValue(HKEY_LOCAL_MACHINE,
            'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
            'UninstallString', uninstaller);
          ShellExec('runas', uninstaller, '/SILENT', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode);
          Result := True;
      end;
    end
    else
    begin
      MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. This installer will exit.',
        mbInformation, MB_OK);
      Result := False;
    end;
  end
  else
  begin
    Result := True;
  end;
end;

Ответ 7

Вы можете выполнить деинсталляцию в разделе [code]. Вы должны выяснить, как получить путь к существующему деинсталлятору. Для простоты, когда я устанавливаю свои приложения, я добавляю значение строки реестра, указывающее на папку, содержащую деинсталлятор, и просто исполняем деинсталлятор в обратном вызове InitializeWizard.

Имейте в виду, что имена деинсталляторов установки Inno имеют форму uninsnnn.exe, вам нужно учитывать это в своем коде.

Ответ 8

Для тех, кто использует предложенный выше GetUninstallString() для принудительного удаления внутри CurStepChanged() и имеет проблемы с кэшированием диска, см. ниже соответствующее решение, которое на самом деле ждет некоторое время после unistallation для удаления exe файла exe! ​​

Проблема с кэшированием диска с помощью inno-setup?

Ответ 9

Мне что-то не хватает. новые файлы копируются в целевой каталог до удаления старой установки. Затем появляется деинсталлятор, который удаляет их и удаляет каталог.

Ответ 10

Не используйте раздел [Выполнить], но [UninstallRun]. Infact, программа под [Run] выполнена после установки, что приведет к удалению вашей программы сразу после установки: - | Вместо этого раздел [UninstallRun] оценивается до.

Ответ 11

Следуйте по этой ссылке: http://news.jrsoftware.org/news/innosetup/msg55323.html

В функции InitializeSetup() вы можете вызвать "MSIEXEC/x {ваш идентификатор программы]" после запроса пользователя для удаления старой старой версии