Функциональные линзы

Может ли кто-нибудь объяснить мне функциональные линзы? Это удивительно сложный вопрос для Google, и я не добился какого-либо прогресса. Все, что я знаю, это то, что они обеспечивают аналогичную функциональность get/set, чем в OO.

ОТВЕТЫ

Ответ 1

Линза состоит из двух функций: геттера и сеттера:

data Lens a b = Lens { getter :: a -> b, setter :: b -> a -> a }

Например, у нас могут быть линзы для первой и второй частей пары:

fstLens :: Lens (a, b) a
fstLens = Lens fst $ \x (a, b) -> (x, b)

sndLens :: Lens (a, b) b
sndLens = Lens snd $ \x (a, b) -> (a, x)

Реальное удобство линз заключается в том, что они составляют:

compose :: Lens b c -> Lens a b -> Lens a c
compose f g = Lens (getter f . getter g) $
                   \c a -> setter g (setter f c (getter g a)) a

И они механически преобразуются в State переходы:

lensGet :: MonadState s m => Lens s a -> m a
lensGet = gets . getter

lensSet :: MonadState s m => Lens s b -> b -> m ()
lensSet f = modify . setter f

lensMod :: MonadState s m => Lens s b -> (b -> b) -> m ()
lensMod f g = modify $ setter f =<< g . getter f

(+=) :: (MonadState s m, Num b) => Lens s b -> b -> m ()
f += x = lensMod f (+ x)