Ответ 1

Возможно, было бы полезно зарегистрировать php.exe как ENVIRONMENT VARIABLE, чтобы командная строка могла распознать команду "php" вместо необходимости вводить полный путь "\ wamp\bin\php\php5.3.8\php" как команда.

Чтобы сделать это, вы можете выполнить шаги, описанные на этой странице: http://windows.fyicenter.com/view.php?ID=60. За исключением шага 5, вместо этого введите путь к WAMP php.exe. Например, просто добавьте $;C:\wamp\bin\php\php5.3.8 в поле Значение переменной. И каждый раз, когда вы открываете свою командную строку, просто запустите php, используя

php pageYouAreRunning.php

.. все еще помня, что pageYouAreRunning.php относится к текущему пути в вашей командной строке.

Ответ 2

Это по существу то же самое, что описано. Вам нужно будет открыть оболочку cmd windows, а затем вам просто нужно найти расположение файла php на вашей конкретной установке.

В установке Wamp я располагаюсь в \wamp\bin\php\php5.3.8\php. Поэтому для запуска PHP скрипт я хочу, я бы назвал...

\wamp\bin\php\php5.3.8\php pageYouAreRunning.php

Имейте в виду, что pageYouAreRunning.php относится к тому пути, который вы сейчас используете в консоли консоли.

Ответ 3

Не тестировалось, но я бы сказал, что это одно и то же...

В вашей папке wamp/php есть "php.exe"...

Запустите его через командную строку:

cd mywamp/php

php -q file.php

Ответ 4

Если php вообще не запущен, создайте пакетный файл со следующим кодом и сохраните его в своей глобальной папке как "php".

"c:\wamp64\bin\php\php7.0.29\php.exe" $1 ${2} ${3} ${4}

Разумеется, замените php7.0.29 тем, что ваша версия php на вашем компьютере
Затем просто запустите любую команду php, как обычно, например

php -v

Если вам нужно больше аргументов, просто добавьте их как необязательные, например $ {5} $ {6}

Ответ 5

Больше не рекомендуется редактировать ваш путь к среде, чтобы напрямую указать путь к PHP exe. Это может привести к головной боли дальше по линии.

Модератор по имени RiggsFoley на форуме phppath.cmd поделился следующим файлом с именем phppath.cmd:

@echo off

REM **********************************************************************
REM * PLACE This file in a folder that is already on your PATH
REM * Or just put it in your C:\Windows folder as that is on the
REM * Serch path by default
REM * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
REM * EDIT THE NEXT 3 Parameters to fit your installed WAMPServer
REM * for example I installed WAMPServer on the D: drive you may
REM * have used C:
REM * - baseWamp : is the drive and folder where you installed WAMPServer
REM * - defaultPHPver : is the version of PHP that will be pathed
REM *                   if no Parameter is put on the bat file
REM * - composerInstalled : Where I insatlled composerInstalled
REM * - phpFolder : The folder structure that contains the Multiple
REM *               possible version of PHP I have installed
REM **********************************************************************


set baseWamp=D:\wamp
set defaultPHPver=7.0.23
set composerInstalled=%baseWamp%\composer
set phpFolder=\bin\php\php

if %1.==. (
    set phpver=%baseWamp%%phpFolder%%defaultPHPver%
) else (
    set phpver=%baseWamp%%phpFolder%%1
)

PATH=%PATH%;%phpver%
php -v
echo ---------------------------------------------------------------


REM IF PEAR IS INSTALLED IN THIS VERSION OF PHP

IF exist %phpver%\pear (
    set PHP_PEAR_SYSCONF_DIR=D:\wamp\bin\php\php%phpver%
    set PHP_PEAR_INSTALL_DIR=D:\wamp\bin\php\php%phpver%\pear
    set PHP_PEAR_DOC_DIR=D:\wamp\bin\php\php%phpver%\docs
    set PHP_PEAR_BIN_DIR=D:\wamp\bin\php\php%phpver%
    set PHP_PEAR_DATA_DIR=D:\wamp\bin\php\php%phpver%\data
    set PHP_PEAR_PHP_BIN=D:\wamp\bin\php\php%phpver%\php.exe
    set PHP_PEAR_TEST_DIR=D:\wamp\bin\php\php%phpver%\tests

    echo PEAR INCLUDED IN THIS CONFIG
    echo ---------------------------------------------------------------
) else (
    echo PEAR DOES NOT EXIST IN THIS VERSION OF php
    echo ---------------------------------------------------------------
)

REM IF COMPOSER EXISTS ADD THAT TOO
REM **************************************************************
REM * IF A GLOBAL COMPOSER EXISTS ADD THAT TOO
REM *
REM * This assumes that composer is installed in /wamp/composer
REM *
REM **************************************************************
IF EXIST %composerInstalled% (
    ECHO COMPOSER INCLUDED IN THIS CONFIG
    echo ---------------------------------------------------------------
    set COMPOSER_HOME=%baseWamp%\composer
    set COMPOSER_CACHE_DIR=%baseWamp%\composer

    PATH=%PATH%;%baseWamp%\composer

    rem echo TO UPDATE COMPOSER do > composer self-update
    echo ---------------------------------------------------------------
) else (
    echo ---------------------------------------------------------------
    echo COMPOSER IS NOT INSTALLED
    echo ---------------------------------------------------------------
)

set baseWamp=
set defaultPHPver=
set composerInstalled=
set phpFolder=

В соответствии с инструкциями вам необходимо отредактировать переменные baseWamp и defaultPHPver. Проверьте папку Wamp bin\php для доступных номеров версий PHP.

Поместите файл в каталог C:\Windows, затем откройте новое командное окно и введите phppath. Теперь у вас будет доступ к php во время этого сеанса окна.